XSLT中的變量範圍

Question

我有一個問題，試圖找出xslt上的var範圍。我實際上想要做的是忽略具有重複「旅遊編碼」的「旅行」標籤。

示例XML：

<trip> 
<tourcode>X1</tourcode> 
<result>Budapest</result> 
</trip> 
<trip> 
<tourcode>X1</tourcode> 
<result>Budapest</result> 
</trip> 
<trip> 
<tourcode>X1</tourcode> 
<result>Budapest</result> 
</trip> 
<trip> 
<tourcode>Y1</tourcode> 
<result>london</result> 
</trip> 
<trip> 
<tourcode>Y1</tourcode> 
<result>london</result> 
</trip> 
<trip> 
<tourcode>Z1</tourcode> 
<result>Rome</result> 
</trip> 

XSLT處理器：

<xsl:for-each select="trip">  
    <xsl:if test="not(tourcode = $temp)"> 
     <xsl:variable name="temp" select="tour"/> 
     // Do Something (Print result!) 
    </xsl:if> 
</xsl:for-each> 

所需的輸出： 布達佩斯倫敦羅馬

Answer 1

所需的輸出：布達佩斯倫敦羅馬

你是什麼後分組按城市名稱輸出。在XSLT中有兩種常用的方法。

其中之一是這樣的：

<xsl:template match="/allTrips"> 
    <xsl:apply-templates select="trip" /> 
</xsl:template> 

<xsl:template match="trip"> 
    <!-- test if there is any preceding <trip> with the same <result> --> 
    <xsl:if test="not(preceding-sibling::trip[result = current()/result])"> 
    <!-- if there is not, output the current <result> --> 
    <xsl:copy-of select="result" /> 
    </xsl:if> 
</xsl:template> 

而另外一個被稱爲Muenchian分組的和@Rubens法里亞斯只是張貼解答，說明如何做到這一點。

Answer 2

您不能更改XSLT中的變量。

因爲XSLT是一種功能性語言，所以您需要更多地考慮它作爲functional programming而不是程序性的。想想像這樣的僞代碼的變量作用域：

variable temp = 5 
call function other() 
print temp 

define function other() 
    variable temp = 10 
    print temp 

你期望輸出是什麼？它應該是10 5而不是10 10，因爲函數other中的temp與該函數外部的temp不是同一個變量。

在XSLT中是一樣的。變量一旦創建，就不能被重新定義，因爲它們是一次寫入的，可以通過設計讀取許多變量。

如果你想有條件地定義一個變量的值，你需要有條件地定義變量，就像這樣：

<xsl:variable name="temp"> 
    <xsl:choose> 
    <xsl:when test="not(tourcode = 'a')"> 
     <xsl:text>b</xsl:text> 
    </xsl:when> 
    <xsl:otherwise> 
     <xsl:text>a</xsl:text> 
    </xsl:otherwise> 
    </xsl:choose> 
</xsl:variable> 
<xsl:if test="$temp = 'b'"> 
    <!-- Do something --> 
</xsl:if> 

只在一個地方定義的變量，但它的價值是有條件的。現在temp的值已設置，它不能在稍後重新定義。在函數式編程中，變量更像只讀參數，因爲它們可以設置，但以後不能更改。爲了在任何函數式編程語言中使用變量，您必須正確理解這一點。

Answer 3

試試這個：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:key name="trip" match="trip" use="result" /> 

    <xsl:template match="/trips"> 

    <xsl:for-each select="trip[count(. | key('trip', result)[1]) = 1]"> 
     <xsl:if test="position() != 1">, </xsl:if> 
     <xsl:value-of select="result"/> 
    </xsl:for-each> 

    </xsl:template> 
</xsl:stylesheet>