parallel :: forkmanager ....如何在出口傳遞2個變量

Question

我正在使用Parallel :: ForkManager將一些變量從子項傳遞給父項。我能夠通過$ var ...我怎麼傳遞更多？ （再次感謝霍布斯幫助我走到這一步）

use Parallel::ForkManager; 

my $pm=new Parallel::ForkManager(10); 
my(@cusips,@bad); 
$pm->run_on_finish(sub{ 
my($pid,$exit_code,$ident,$exit_signal,$core_dump,$var,$v)=@_; 
print "pid: ".$pid."\n"; 
print " first: ".${$var}."\n"; 
print " second: ".${$v}."\n"; 
}); 


for(1..3){ 

$pm->start and next; # do the fork 
my $var=rand(); 
my $v=rand(); 

$pm->finish(0,\$var,\$v); # do the exit in the child process 
} 


$pm->wait_all_children; 

Answer 1

只能有一個:)

傳遞一個數組引用：

$pm->finish(0, [ $var, $v ]); 

或哈希參考：

$pm->finish(0, { 'var' => $var, 'v' => $v }); 

And：

$pm->run_on_finish(sub{ 
    my ($pid,$exit_code,$ident,$exit_signal,$core_dump,$data)=@_; 
    print "pid: ".$pid."\n"; 
    print " first: ".$data->[0]."\n"; 
    print " second: ".$data->[1]."\n"; 
}); 

或

$pm->run_on_finish(sub{ 
    my ($pid,$exit_code,$ident,$exit_signal,$core_dump,$data)=@_; 
    print "pid: ".$pid."\n"; 
    print " first: ".$data->{'var'}."\n"; 
    print " second: ".$data->{'v'}."\n"; 
});