VIM有多於一個的標誌

Question

我有一個調試文件看起來像這樣摺疊：

==>func1: 
..... 
.. 
==>func2: 
...... 
... 
<==func2 
.. 
<==func1 
==>func3: 
...... 
... 
<==func3 

基本上，我想能夠摺疊的功能，最終看到這樣的事情每個人：

+-- x lines: ==> func1: 
+-- x lines: ==> func3: 

，但仍然能夠擴大func1，看到func2摺疊：

==>func1: 
..... 
.. 
+-- x lines: ==> func2: 
.. 
<==func1 

有沒有辦法做到這一點？謝謝。

Answer 1

無與倫比的標記需要額外的手柄，這裏是一個EXPR溶液（見:h fold-expr）：

setlocal foldmethod=expr 
setlocal foldexpr=GetFoldlevel(v:lnum) 

function GetFoldlevel(lnum) 
    let line = getline(a:lnum) 

    let ret = '=' 
    if line[0:2] == '==>' 
     let name = matchstr(line, '^==>\zs\w*') 
     let has_match = HasMarkerMatch(a:lnum, name) 
     if has_match 
      let ret = 'a1' 
     endif 
    elseif line[0:2] == '<==' 
     let ret ='s1' 
    endif 

    return ret 
endfunction 

function HasMarkerMatch(lnum, name) 
    let endline = line('$') 
    let current = a:lnum + 1 

    let has_match = 0 
    while current <= endline 
     let line = getline(current) 

     if line =~ '^<=='.a:name 
      let has_match = 1 
      break 
     endif 

     let current += 1 
    endwhile 

    return has_match 
endfunction