Scilab的符號矩陣乘法

我有3個矩陣：Scilab的符號矩陣乘法

T_01 = ['cosd*t1', '-sind*t1', '0', 'd1*cosd*t1'; 'sind*t1', 'cosd*t1', '0', 'd1*sind*t1'; '0', '1', '1', '0'; '0', '0', '0', '1'] 

T_12 = ['cosd*t2', '-sind*t2', '0', 'd2*cosd*t2'; 'sind*t2', 'cosd*t2', '0', 'd2*sind*t2'; '0', '1', '1', '0'; '0', '0', '0', '1'] 

T_23 = ['cosd*t3', '-sind*t3', '0', 'd3*cosd*t3'; 'sind*t3', 'cosd*t3', '0', 'd3*sind*t3'; '0', '1', '1', '0'; '0', '0', '0', '1']

我需要做一個符號乘法，所以我想：

mulf(T_01,T_12,T_23)

但我得到這個錯誤：

     !--error 39 
mulf: Quantidade incorreta de argumentos de entrada: esperava-se 2.

發生了什麼？

Obs .:對不起，我的英語。

來源

2017-10-21 Eliu Moraes

mulf功能只需要2個參數。由於乘法是關聯的，即a * b * c = a *（b * c），所以可以嘗試mulf（T_01，mulf（T_12，T_23））''。然後再次，你會得到另一個錯誤，因爲矩陣不能是這個函數的輸入。你到底想做什麼？你能澄清嗎？也許你可以告訴我們你期望得到的結果是什麼。 – luispauloml

如果你想要得到兩個矩陣的符號乘法，你必須實現這樣的功能。這裏我已經實現了三個功能，它們可以一起執行你想要的功能：

function s = scaProd(a,b) 
    //escalar product of two vectors 
    //using recursion 

    if (a == [] | b == []) then 
     s = "" 

    elseif (max(size(a)) ~= max(size(b))) | ... 
      (min(size(a)) ~= min(size(b))) | ... 
      (min(size(a)) ~= 1) then 
     error("vectorMulf: Wrong dimensions") 

    else 
     s = addf(mulf(a(1), b(1)) , scaProd(a(2:$), b(2:$))) 

    end 
endfunction 

function s = matrixMulf(a,b) 
    //matrix multiplication 

    acols = size(a,'c'); 
    brows = size(b,'r'); 
    if acols ~= brows then 
     error("matrixMulf: Wrong dimensions") 
    end 

    arows = size(a,'r'); 
    bcols = size(b,'c'); 
    s = string(zeros(arows,bcols)); 

    for i = 1 : arows 
     for j = 1 : bcols 
      s(i,j) = scaProd(a(i,:),b(:,j)'); 
     end 
    end 
endfunction 

function s = addP(a) 
    //encolses each element of a in a pair of parenthesis 
    s = string(zeros(a)); 

    for i = 1 : size(a,'r') 
     for j = 1 : size(a,'c') 
      s(i,j) = "(" + a(i,j) + ")" 
     end 
    end 
endfunction

下面是它的輸出示例。測試代碼：

A = [1 2; 3 4]; 
B = [5 6; 7 8]; 
C = [9 0; 1 2]; 
disp(A*B*C) 
As = string(A); 
Bs = string(B); 
Cs = string(C); 
disp(matrixMulf(As,addP(matrixMulf(Bs, Cs))))

控制檯輸出：

193. 44. 
    437. 100. 

!1*(5*9+6*1)+2*(7*9+8*1) 1*(5*0+6*2)+2*(7*0+8*2) ! 
!             ! 
!3*(5*9+6*1)+4*(7*9+8*1) 3*(5*0+6*2)+4*(7*0+8*2) !

對於你想要的結果，你應該做的：

附上每個矩陣用括號的各項條款使用addP()
執行像matrixMulf(t1,addP(matrixMulf(t2,t3)))這樣的符號乘法，其中t1，t2，t3是你的矩陣的封閉版本。

和兩個最後說明：

使用addP在每個相乘步驟，以獲得正確的結果是很重要的。您可以通過在我給出的示例中刪除(和)來檢查：結果將不正確。
功能mulf和addf在Scilab 6.0.0上不可用。所以請記住，如果您將Scilab升級到當前穩定版本，您將無法使用它們。

來源

2017-10-22 02:36:27 luispauloml

Scilab的符號矩陣乘法

回答

相關問題