陰影沿Y軸有界區域

Question

我畫了一條線，但想要沿着Y軸陰影2和4之間的區域來說明曲線下的區域，但無法弄清楚如何做到這一點，任何人都可以幫忙嗎？這是代碼，這是相當簡單的

>y:=(2*x); 

>plot(y,x=0..3); 

Answer 1

我很難理解你的想法正是區域。

這是嗎？

restart; 

y := 2*x: 

plots:-display(
    plot(2*x, x=0..3), 
    plots:-inequal([Y>=y, Y>=2, Y<=4], x=0..3, Y=0..6, 
       'nolines', 'color'="Burgundy") 
); 

當然，你可以省略曲線（線）y=2*x by刪除通話以上plot。

如果您有其他地區，那麼您應該可以相應地調整plots:-inequal。

還有其他方法可以完成此類操作，例如撥打plot並選擇其filled選項。您也可以使用plottools:-reflect或使用參數調用順序plot來翻轉軸x和y。

我想，你可能會想，以避免「解決對於x」，得到相應y=2和y=4x值（即使在y=2*x這個例子中，你可以做，在你的頭）。

這些原因讓我覺得你可以用plots:-inequal來找到它最簡單。

[編輯：用於後續評論約8矩形]

首先，略微不同的實施例，希望更加清晰。

restart; 

x:=arcsin(y/6): 

P := plots:-display(
    plot(x, y=2..5), 
    plots:-inequal([X<=x], y=2..5, X=0..1.2, 
       'nolines', 'color'=pink) 
): 

plots:-display(
    plot(2, color=black, linestyle=dot), 
    plot(5, color=black, linestyle=dot), 
    plot([x, y, y=0..6]), 
    plottools:-transform((x,y)->[y,x])(P), 
    view=[0..1.2,0..6], 
    labels=["x","y"], 
    size=[500,300] 
); 

下款項（使用矩形）的上可以使用RiemannSum命令從Student:-Calculus1包被可視化。 （或者你可以使用seq命令並通過它們的角落公式來構建它們 - 但這看起來像是很多笨拙的簿記。）

您當然可以刪除下面傳遞給plots:-display命令的任何部分。

restart; 

with(Student:-Calculus1): 

x:=arcsin(y/6): 

P:=RiemannSum(x, y=2..5, method = upper, output = plot, 
       partition=8, 
       boxoptions=[filled=[color=pink,transparency=.5]], 
       caption=""): 

rP:=plottools:-transform((x,y)->[y,x])(P): 

plots:-display(
    plot(2, color=black, linestyle=dot), 
    plot(5, color=black, linestyle=dot), 
    plot([x, y, y=0..6]), 
    rP, 
    view=[0..1.2,0..6], 
    labels=["x","y"], 
    size=[500,300] 
); 

或者，

restart; 

with(Student:-Calculus1): 

x:=arcsin(y/6): 

P:=RiemannSum(x, y=2..5, method = lower, output = plot, 
       partition=8, 
       boxoptions=[filled=[color=pink,transparency=.5]], 
       caption=""): 

rP:=plottools:-transform((x,y)->[y,x])(P): 

plots:-display(
    plot(2, color=black, linestyle=dot), 
    plot(5, color=black, linestyle=dot), 
    plot([x, y, y=0..6]), 
    rP, 
    view=[0..1.2,0..6], 
    labels=["x","y"], 
    size=[500,300] 
); 

所有這些例子會少一點複雜，如果你想要的曲線與x軸，而不是之間的區域。