帶有修改的XSLT副本

Question

我被困在試圖在這些限制內工作，我正在使用XSLT 1.0 {under .net}。 我希望能夠做到以下幾點： 我是的xsl：for-each'ing通過一組類型的節點的

<node> 
    <data> unknown unstructured xml </data> 
    <owner></owner> 
    </node> 

我想能夠輸出

<node> 
    <data> unknown unstructured xml </data> 
    <!--RESULT of calling an XSL template with certain parameters --> 
    </node> 

從我的搜索到目前爲止，我想我可以做這樣的事情在here：

<xsl:copy> 
     <xsl:apply-template name="findownerdetails"> 
      <xsl:with-param name="data" select="something" /> 
     </xsl:apply-template> 
    </xsl:copy> 

但這顯然是無效的。任何建議如何得到這個工作或實現類似的目標？恐怕我不能直接調用apply-templates作爲我想要的模板，這取決於我爲每個節點元素創建的數據。

任何意見理解

Answer 1

<xsl:template match="node"> 
    <node> 
    <xsl:copy-of select="data"/> 
    <!-- assuming this next bit in your question example 
    is something you are happy with --> 
    <xsl:call-template name="findownerdetails"> 
     <xsl:with-param name="data" select="something" /> 
    </xsl:call-template> 
    </node> 
</xsl:template> 

Answer 2

這是最好的使用並覆蓋解決的問題的一個典型的例子的identity rule：

<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output omit-xml-declaration="yes" indent="yes"/> 
    <xsl:strip-space elements="*"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="owner"> 
    <owner-details> 
     <xsl:value-of select="."/> 
    </owner-details> 
</xsl:template> 
</xsl:stylesheet> 

當這種轉化是在這個XML施加文檔（基於所提供的具有附加屬性和所有者詳細信息的XML文檔）：

<node attr1="x" attr2="y"> 
    <data> unknown unstructured xml </data> 
    <owner> 
     <details> 
      <name>John Smith </name> 
      <profession>XSLT programmer</profession> 
     </details> 
    </owner> 
</node> 

的通緝的結果產生：

<node attr1="x" attr2="y"> 
    <data> unknown unstructured xml </data> 
    <owner-details>John Smith XSLT programmer</owner-details> 
</node> 

請注意：

1. 身份模板拷貝文檔中的每個節點 「原樣」 的遞歸的時尚。

2. 我們只覆蓋我們想要以另一種方式處理的元素的標識模板。任何模板（其匹配模式比標識模板的匹配模式更具體）都會覆蓋它--XSLT處理器將始終爲節點選擇最具體的匹配模板。

3. 使用並重寫身份規則是最根本的，功能最強大，最普遍和最優雅的XSLT設計模式。它幾乎在所有XSLT轉換中都使用：用於刪除/重命名/修改/添加特定節點並保持所有其他節點不變。

4. OP在評論中建議此解決方案不允許傳遞參數。這不是真的。任何模板（包括身份規則）都可以寫入參數 - 當需要時。在這種特殊情況下，它是而不是需要通過模板傳遞參數。

5. 匹配owner模板不需要調用另一個模板 - 所有的老闆 - 具體的處理都可以在這裏完成。