這是XSLT效率低下嗎？

Question

我從my last question about translating an XML file得到了答案，它激勵我玩它。我想出了一個不同的解決方案，但我覺得最後兩個選擇是不理想的。這可以以更好的方式完成還是更高效？

樣式表：

<xsl:stylesheet version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output omit-xml-declaration="yes" indent="yes"/> 
    <xsl:strip-space elements="*"/> 

    <xsl:param name="pFrom" select="'en'"/> 
    <xsl:param name="pTo" select="'de'"/> 


    <xsl:variable name="translations" select="document('translations.xml')"/> 

    <xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="@name"> 
    <xsl:variable name="thisname" select="." /> 

    <xsl:variable name="entry" select="$translations/translations/entry[attribute::node()[name()=$pFrom and $thisname=.]]"></xsl:variable> 
    <xsl:attribute name="name" select="$entry/attribute::node()[local-name() = $pTo]"></xsl:attribute> 
    </xsl:template> 
</xsl:stylesheet> 

來源：

<?xml version="1.0" encoding="UTF-8"?> 
<grammar> 
    <element name="table" /> 
    <element name="chair" /> 
</grammar> 

和翻譯文件（translations.xml）：

<?xml version="1.0" encoding="UTF-8"?> 
<translations> 
    <entry en="table" de="Tisch" fr="Table" /> 
    <entry en="chair" de="Stuhl" fr="Chaise"/> 
</translations> 

結果是：

<grammar> 
    <element name="Tisch"/> 
    <element name="Stuhl"/> 
</grammar> 

一個例子：當我從「恩」去「德」，我在源文件中的第一name屬性（「表」），我看着翻譯文件爲EN條目，其中EN =「表」併爲名稱選擇'de'屬性。

Answer 1

使用鍵：

<xsl:key name="en" match="translations/entry" use="@en"/> 
<xsl:key name="de" match="translations/entry" use="@de"/> 
<xsl:key name="fr" match="translations/entry" use="@fr"/> 

然後

<xsl:template match="@name"> 
    <xsl:attribute name="name" select="key($pFrom, current(), $translatations)/@*[local-name() = $pTo]"/> 
    </xsl:template> 

（我假設你使用XSLT 2.0）。