VBA中的連續單元格值

Question

是否可以將連續單元格值與單個單元格進行比較？例如：

If Sheets("Sheet2").Range("E4:E6").Value = Sheets("Sheet1").Range("D4").Value Then 

.... 

我試過，但顯示錯誤TYPEMISMATCH

Answer 1

嘗試

Sheets("Sheet2").Range("E4:E6") = Sheets("Sheet1").Range("D4").Value 

如果沒有，那麼你需要一個循環：

c = true 
for each i in Sheets("Sheet2").Range("E4:E6") 
    If i <> Sheets("Sheet1").Range("D4").Value then 
     c = false 
     Exit for 
    End if 
Next 
If c then 
..... 

Answer 2

表達Sheets("Sheet2").Range("E4:E6").Value返回包含這些單元格中的值的二維數組。正如你所看到的，你不能用一個平等運算符來比較一個值。

如果你想看看是否能值存在，你可以使用匹配工作表函數這樣

Sub FindMatch() 

    Dim lMatch As Long 

    On Error Resume Next 
     lMatch = Application.WorksheetFunction.Match(Range("D4").Value, Range("E4:E6").Value, False) 
    On Error GoTo 0 

    If lMatch > 0 Then 
     Debug.Print "Value exists" 
    Else 
     Debug.Print "Not included" 
    End If 

End Sub 

如果你想，以確定是否在範圍內的所有值都是一樣的，你可以使用像這樣的Sumif

Sub FindAllMatch() 

    Dim dSum As Double 

    If Application.WorksheetFunction.Sum(Range("E4:E6")) = Application.WorksheetFunction.SumIf(Range("E4:E6"), Range("D4").Value) Then 
     Debug.Print "All match" 
    Else 
     Debug.Print "One doesn't match" 
    End If 

End Sub 

另一種選擇是Filter VBA函數，該函數返回按某些條件過濾的數組。過濾器需要一維數組和Range（）。Value返回一個二維數組，因此您必須使用Transpose函數來進行該轉換。

Sub Findmatch2() 

    Dim vaOneD As Variant 
    Dim sMatch As String 

    sMatch = Range("D4").Value 

    vaOneD = Application.WorksheetFunction.Transpose(Range("E4:E6").Value) 

    If UBound(Filter(vaOneD, sMatch, True)) > -1 Then 
     Debug.Print "There's a match" 
    Else 
     Debug.Print "No match" 
    End If 

End Sub 

要檢查所有的價值都是一樣的，適當的行更改爲

If UBound(Filter(vaOneD, sMatch, True)) - LBound(Filter(vaOneD, sMatch, True)) = UBound(vaOneD) - LBound(vaOneD) Then