計算流逝與時代

Question

我創建了一個函數，它接受兩個日期，並返回描述時間這樣的兩個日期之間的時間：

1年3個月2周1天10小時

我現在面臨的問題使用此功能的是，如果持續時間少於一個月，但如果兩個日期屬於不同月份，則返回月份持續時間。

有人可以幫我調整這個功能嗎？

您可以在這裏找到查詢：

http://data.stackexchange.com/stackoverflow/query/edit/149306

正如你可以看到我傳遞的開始日期爲2013-08-29 13:48:35.710和結束日期爲2013-09-03 17:04:27.493並應返回時間爲5 days 3 hours 15 minutes但它返回1月3小時15分鐘。

我該如何調整它以顯示正確的持續時間？

Answer 1

DECLARE @date1 DATETIME, @date2 DATETIME 
DECLARE @result VARCHAR(100) 
DECLARE @years BIGINT, @months BIGINT, @weeks BIGINT, @days BIGINT, @hours BIGINT, @minutes BIGINT 
DECLARE @KEEP DATETIME 

SET @date1 = '20130829 13:48:35.710' 
SET @date2 = '20130903 17:04:27.493' 

if @date1>@date2 
begin 
    SET @KEEP=@date1 
    SET @date1=@date2 
    SET @date2=@KEEP 
end 

Select @years=DATEDIFF(yy,@date1,@date2) 
if DateAdd(yy,-@years,@date2)<@date1 Select @years=@years-1 
Set @date2= DateAdd(yy,-@years,@date2) 

Select @months=DATEDIFF(mm,@date1,@date2) 
if DateAdd(mm,-@months,@date2)<@date1 Select @months=@months-1 
Set @date2= DateAdd(mm,-@months,@date2) 

Select @weeks=DATEDIFF(wk,@date1,@date2) 
if DateAdd(wk,-@weeks,@date2)<@date1 Select @weeks=@weeks-1 
Set @date2= DateAdd(wk,-@weeks,@date2)   

Select @days=DATEDIFF(dd,@date1,@date2) 
if DateAdd(dd,-@days,@date2)<@date1 Select @days=@days-1 
Set @date2= DateAdd(dd,-@days,@date2) 

Select @hours=DATEDIFF(hh,@date1,@date2) 
if DateAdd(hh,-@hours,@date2)<@date1 Select @hours=@hours-1 
Set @date2= DateAdd(hh,-@hours,@date2) 

Select @minutes=DATEDIFF(mi,@date1,@date2) 

Select @result= ISNULL(CAST(NULLIF(@years,0) as varchar(10)) + ' Years','') 
    + ISNULL(' ' + CAST(NULLIF(@months,0) as varchar(10)) + ' Months','') 
    + ISNULL(' ' + CAST(NULLIF(@weeks,0) as varchar(10)) + ' Weeks','')  
    + ISNULL(' ' + CAST(NULLIF(@days,0) as varchar(10)) + ' Days','') 
    + ISNULL(' ' + CAST(NULLIF(@hours,0) as varchar(10)) + ' Hours','') 
    + ISNULL(' ' + CAST(@minutes as varchar(10)) + ' Minutes','') 

Select @result  

-- OUTPUT : 5 Days 3 Hours 16 Minutes