嵌套到批處理變量中的批處理變量

Question

根據「x」之後和mypath變量中的「打開文件」之前的文本，我想調用傳遞此文本作爲參數的函數，以便將其替換爲'foo'。要做到這一點，我已經寫了

@echo off 
SET mypath=Y:\SUT\ISTQB\Board Airport\X\Dashboard\Open file 
if /i %1=="Dashboard" goto label %1 
if /i %1=="Dboard" goto label %1 

:label 
SET mypath=%mypath:\%1\=foo% 
ECHO %mypath% 

我注意到，在這個腳本結束呼應mypath中輸出

Y:\SUT\ISTQB\Board Airport\X\Dashboard\Open file instead of 
Y:\SUT\ISTQB\Board Airport\X\foo\Open file 

我認爲這個問題是有關參數％1「SET mypath中=％mypath中內：\％1 \ = foo％'，但我不明白爲什麼。

事實上，我絕對需要使用參數％1，因爲當前「儀表板」中的文本變爲mypath變量不是靜態文本。它可以是「Dboard」，或任何東西

有人可以解釋我嗎？預先感謝您

Answer 1

對於字符串操作與變量，你需要delayed expansion：

@echo off 
SET mypath=Y:\SUT\ISTQB\Board Airport\X\Dashboard\Open file 
if /i %1=="Dashboard" goto label %1 
if /i %1=="Dboard" goto label %1 

:label 
setlocal enabledelayedexpansion 
SET mypath=!mypath:\%~1\=foo! 
ECHO %mypath% 

..output是：

Y:\SUT\ISTQB\Board Airport\XfooOpen file 

Answer 2

 @echo off 
     SET mypath=Y:\SUT\ISTQB\Board Airport\X\Dashboard\Open file 

     if /i "%~1"=="Dashboard" goto :label 
     if /i "%~1"=="Dboard" goto :label 

     goto :eof 
     :label 
     rem set temp_var=%~1 
     rem call SET mypath=%%mypath:%temp_var%=foo%% 
     rem echo %mypath% 
    setlocal enabledelayedexpansion 
     set mypath=!mypath:%~1=foo! 
     ECHO !mypath! 
    endlocal 

你能試試嗎？

Answer 3

你的問題是使用%1查找/替換： -
SET mypath=%mypath:\%1\=foo%有太多%字符使語法有點不安。

這個答案是使用EnableDelayedExpansion趁!語法，但要注意endlocal後％mypath中％變量將失去它的價值 - 它不僅保持了setlocal塊內的值。解決此

一種方式是寫SET命令到一個臨時批處理文件，並在局部塊之後調用它：

setlocal EnableDelayedExpansion 
    SET mypath=!mypath:%1=foo! 
    rem Create a batch file to perform SET later : 
    echo @SET mypath=%mypath% > "%TEMP%\setmyvar.bat" 
endlocal 

    rem Now use the batch file to set the variable : 
call "%TEMP%\setmyvar.bat" 
ECHO %mypath% 

如果有一個更優雅的方式來做到這一點，請讓我們知道： ）

Answer 4

不好意思。有時我覺得我並不真正理解這些問題（也許是因爲我的母語不是英語）。

在你的問題中，你說你想用'foo'替換「'X'之後和'打開文件'之前的文本...'甚至你說'現在是」儀表板「的文本變成mypath變量不是一個靜態文本，它可以是「Dboard」或其他任何東西「，但是在你的代碼和後面的答案中，你似乎只想通過」foo「改變字符串」Dashboard「或者」Dboard「 。這讓我困惑。

無論如何，這是我的解決方案您的問題（不是您的意見）。

@echo off 
setlocal EnableDelayedExpansion 

SET mypath=Y:\SUT\ISTQB\Board Airport\X\Dashboard\Open file 

rem Get the text after 'X' and before 'Open file' 
set auxPath=%mypath% 
set enclosed= 
set text= 
:nextPart 
    for /F "tokens=1* delims=\" %%a in ("%auxPath%") do (
     if "%%a" equ "Open file" (set enclosed=) else (
     if defined enclosed (set "text=!text!\%%a") else (
     if "%%a" equ "X" (set enclosed=1) 
    )) 
     set "auxPath=%%b" 
    ) 
if defined auxPath goto nextPart 
set text=%text:~1% 

rem Replace that text by "foo" 
call :Change "%text%" 
goto :EOF 

:Change 
SET mypath=!mypath:\%~1\=\foo\! 
ECHO %mypath% 
exit /B 

例如，以前的程序的輸出是這樣的：

Y:\SUT\ISTQB\Board Airport\X\foo\Open file 

但如果myPath變量中會是這樣：

Y:\SUT\ISTQB\Board Airport\X\One\Two three\Open file 

...輸出將是這樣：

Y:\SUT\ISTQB\Board Airport\X\foo\Open file 

......這正好解決了y我們的要求。