從用戶定義函數

Question

我發現這個用戶自定義功能列出訪問數據庫中的所有表從創建值組合框

Function dmwListAllTables() As String 

Dim tbl As AccessObject, db As Object 
Dim strMsg As String 

On Error GoTo Error_Handler 

Set db = Application.CurrentData 
For Each tbl In db.AllTables 
Debug.Print tbl.Name 
Next tbl 

strMsg = " -- Tables listing complete -- " 

Procedure_Done: 
dmwListAllTables = strMsg 
Exit Function 

Error_Handler: 
strMsg = Err.Number & " " & Err.Description 
Resume Procedure_Done 

End Function 

此函數最初設計用於將當前數據庫中的所有表名打印到即時窗口，但是我正在尋找一種方法將dmwListAllTables()輸出作爲具有組合框的窗體中使用的值。這項壯舉可能嗎？

由於提前，

dubbbdan

Answer 1

我肯定可以修改代碼，做你想做的。只是一個問題，你希望在什麼時候發生這種情況。當窗體加載或單擊按鈕時，ComboBox是否需要填充表的名稱？所有你需要做的是一樣的東西，（對於一個簡單的例子，我將加載窗體時使用），

Private Sub Form_Load() 
    Me.comboBoxName.RowSourceType = "Value List" 
    Me.comboBoxName.RowSource = dmwListAllTables() 
End Sub 

然後你的函數被修改爲，

Function dmwListAllTables() As String 
    Dim tbl As AccessObject, db As Object 
    Dim strMsg As String 
On Error GoTo Error_Handler 
    Set db = Application.CurrentData 

    For Each tbl In db.AllTables 
     strMsg = strMsg & tbl.Name & ";" 
    Next tbl 

Procedure_Done: 
    dmwListAllTables = strMsg 
    Exit Function 

Error_Handler: 
    strMsg = Err.Number & " " & Err.Description 
    Resume Procedure_Done 
End Function