SAS保留聲明 - 如何將以前的非缺失值保留在新列中以進行比較

Question

我只是想創建一個保留上一記錄中特定列的值的新列，以便我可以將現有列與新專欄。更進一步，我希望能夠輸出記錄，使兩列中的值不同並丟失值相同的記錄。

本質上，我希望我的數據集看起來像這樣，其中第一個idr具有保留日期設置爲空：

Idr Date1   Date2 
1 20/01/2016 . 
1 20/01/2016 20/01/2016 
1 18/10/2016 20/01/2016 
2 07/03/2016 . 
2 18/05/2016 07/03/2016 
2 21/10/2016 18/05/2016 
3 29/01/2016 . 
3 04/02/2016 29/01/2016 
3 04/02/2016 04/02/2016 

我已經沿着過去以下行由此我已經創建了一個臨時變量引用數據欲保留使用的代碼：

date_temp=date1; 
    data example2; 
    set example1; 
    by idr date1; 
    date_temp=date1; 
retain date_temp ; 
    if first.idr then do; 
     date_temp=date1; 
    end;else do; 
     date2=date_temp; 
    end; 
run; 

我已經搜索了谷歌的高點和低點 - 任何h elp將不勝感激

Answer 1

這裏的技巧是在已經輸出當前行之後爲下一行設置保留變量的值，而不是依賴數據末尾的默認隱式輸出步：

data example2; 
    set example1; 
    by idr; 
    retain date2; 
    if first.idr then call missing(date2); 
    output; 
    date2 = date1; 
    format date2 ddmmyy10.; 
run; 

邏輯輸出語句後執行不會對一個剛剛輸出的行中的任何區別，但直到數據步驟的繼續進行下一次迭代，一切都還處於PDV，包括變量保留在下一行，所以這是一個更新它們的機會。 More details on the PDV。

這樣做，使用lag功能的另一種方式：

data example3; 
    set example1; 
    date2 = lag(date1); 
    if idr ne lag(idr) then call missing(date2); 
run; 

使用lag時要小心 - 它返回從lag功能的該實例中的數據的步驟，而不是在執行最後一次值必然是前一行的那個變量的值，所以如果你做類似if condition then mylaggedvar=lag(var);

Answer 2

這樣的奇怪事情往往會發生爲了實現你的最終結果（刪除idr和日期與前一行相同的記錄），你可以輕鬆您可以在不創建額外列的情況下實現此目標提供數據按idr和date1排序，然後使用first.date1保留所需的記錄。

data have; 
input Idr Date1 :ddmmyy10.; 
format date1 ddmmyy10.; 
datalines; 
1 20/01/2016 
1 20/01/2016 
1 18/10/2016 
2 07/03/2016 
2 18/05/2016 
2 21/10/2016 
3 29/01/2016 
3 04/02/2016 
3 04/02/2016 
; 
run; 

data want; 
set have; 
by idr date1; 
if first.date1 then output; 
run;