來自野牛的ANTLR語法

Question

我正在嘗試將一個語法從野牛翻譯成ANTLR。語法本身在野牛中非常簡單，但我找不到一個簡單的方法來完成這個任務。

語法野牛：

expr = expr or expr | expr and expr | (expr) 

任何提示/鏈接/指針是歡迎的。

感謝， 尤利安

Answer 1

在ANTLR，你不能創建左遞歸規則：

a : a b 
    ; 

尾遞歸是好的：

a : b a 
    ; 

有關左遞歸規則的詳細信息，請參閱ANTLR's Wiki。

所以，你的例子看起來是這樣：

parse 
    : expr+ EOF 
    ; 

expr 
    : orExpr 
    ; 

orExpr 
    : andExpr ('or' andExpr)* 
    ; 

andExpr 
    : atom ('and' atom)* 
    ; 

atom 
    : Boolean 
    | '(' expr ')' 
    ; 

Boolean 
    : 'true' 
    | 'false' 
    ; 

這裏有一個小的演示中的Java：

grammar BoolExp; 

@members { 
    public static void main(String[] args) throws Exception { 
    if(args.length != 1) { 
     System.out.println("Usage:"); 
     System.out.println(" - Windows : java -cp .:antlr-3.2.jar BoolExpParser \"EXPRESSION\""); 
     System.out.println(" - *nix/MacOS : java -cp .;antlr-3.2.jar BoolExpParser \"EXPRESSION\""); 
     System.exit(0); 
    } 
    ANTLRStringStream in = new ANTLRStringStream(args[0]); 
    BoolExpLexer lexer = new BoolExpLexer(in); 
    CommonTokenStream tokens = new CommonTokenStream(lexer); 
    BoolExpParser parser = new BoolExpParser(tokens); 
    parser.parse(); 
    } 
} 

parse 
    : e=expr EOF {System.out.println($e.bool);} 
    ; 

expr returns [boolean bool] 
    : e=orExpr {$bool = $e.bool;} 
    ; 

orExpr returns [boolean bool] 
    : e1=andExpr  {$bool = $e1.bool;} 
    ('or' e2=andExpr {$bool = $bool || $e2.bool;} 
    )* 
    ; 

andExpr returns [boolean bool] 
    : e1=atom  {$bool = $e1.bool;} 
    ('and' e2=atom {$bool = $bool && $e2.bool;} 
    )* 
    ; 

atom returns [boolean bool] 
    : b=Boolean  {$bool = new Boolean($b.text).booleanValue();} 
    | '(' e=expr ')' {$bool = $e.bool;} 
    ; 

Boolean 
    : 'true' 
    | 'false' 
    ; 

Space 
    : (' ' | '\t' | '\n' | '\r') {skip();} 
    ; 

首先創建一個詞法&分析器（1），然後編譯所有的源文件（2 ）。最後，執行BoolExpParser類（3）。

// Windows & *nix/MacOS 
java -cp antlr-3.2.jar org.antlr.Tool BoolExp.g 

// Windows 
javac -cp .;antlr-3.2.jar *.java 

// *nix/MacOS 
javac -cp .:antlr-3.2.jar *.java 

// Windows 
java -cp .;antlr-3.2.jar BoolExpParser "false and true or true" 

// *nix/MacOS 
java -cp .:antlr-3.2.jar BoolExpParser "false and true or true" 

Terence Parr的ANTLR reference是上ANTLR書。 Scott在ANTLR 3上創建了一些優秀的video tutorials（使用Eclipse）。