運行時加載外部資產並在actionscript 3中重新使用預加載的資產？

Question

我正在創建一個2d flash遊戲（在flex/actionscript 3中編碼），在需要時下載資源。目前，我有它的設置是這樣的：

AssetLoader.as

package 
{ 
    import flash.display.Loader; 
    import flash.net.URLRequest; 

    public class AssetLoader extends Loader 
    { 
     //set vars 
     private var url:String = "http://test.com/client/assets/"; 

     public function AssetLoader(url:String) 
     { 
      Logger.log("AssetLoader request: " + this.url + url); 
      var request:URLRequest = new URLRequest(this.url + url); 
      this.load(request); 
     } 
    } 
} 

然後，在這裏我要加載的資產我做到以下幾點：

var asset:AssetLoader = new AssetLoader("ships/" + graphicId + ".gif"); 
asset.contentLoaderInfo.addEventListener(Event.COMPLETE, onShipAssetComplete, false, 0, true); 

private function onShipAssetComplete(event:Event):void 
{ 
    var loader:Loader = Loader(event.target.loader); 
     shipImage = Bitmap(loader.content); 
     shipImage.smoothing = true; 
     addChild(shipImage); 
} 

的事情是，這種方法不檢查已經下載的資產，所以它會在第二次請求同樣的資產時重新下載它們（我認爲）。

所以，我需要的是一個數組，其中存儲了所有下載的資產，並根據請求檢查此資產的名稱是否存在於數組中。所以如果它已經被下載，那麼來自內存的資源必須被返回而不是被重新下載。

我可以使assetloader一個靜態類，但我必須等待事件時，它的完成下載圖像火 - 所以我不能簡單地讓一個靜態函數返回相應的圖像。任何想法我應該如何做到這一點？

編輯徵求意見後企圖：

package 
{ 
    import flash.display.Loader; 
    import flash.events.Event; 
    import flash.net.URLRequest; 

    public final class AssetManager 
    { 
     private static var assets:Object = {}; 
     private static var preUrl:String = Settings.ASSETS_PRE_URL; 

     public static function load(postUrl:String):* 
     { 
      if (assets[postUrl]) 
      { //when the asset already exists 
       //continue 
      } 
      else 
      { //the asset still has to be downloaded 
       var request:URLRequest = new URLRequest(preUrl + postUrl); 
       var loader:Loader = new Loader(); 
       loader.load(request); 
       loader.contentLoaderInfo.addEventListener(Event.COMPLETE, 
       function(event:Event):void 
       { 
        var loader:Loader = Loader(event.target.loader); 
        assets[postUrl] = loader.content; 
       }, false, 0, true); 
      } 
     } 
    } 
} 

EDIT2：另一種嘗試

package 
{ 
    import flash.display.Loader; 
    import flash.events.Event; 
    import flash.events.EventDispatcher; 
    import flash.net.URLRequest; 

    public final class AssetManager 
    { 
     private static var assets:Object = {}; 
     private static var preUrl:String = Settings.ASSETS_PRE_URL; 

     public static function load(postUrl:String):* 
     { 
      if (assets[postUrl]) 
      { //the asset already exists 
       var dispatcher:EventDispatcher = new EventDispatcher(); 
       dispatcher.dispatchEvent(new CustomEvent(CustomEvent.LOAD_COMPLETE, assets[postUrl])); 
      } 
      else 
      { //the asset still has to be downloaded 
       var request:URLRequest = new URLRequest(preUrl + postUrl); 
       var loader:Loader = new Loader(); 
       loader.load(request); 
       loader.contentLoaderInfo.addEventListener(Event.COMPLETE, 
       function(event:Event):void 
       { 
        var loader:Loader = Loader(event.target.loader); 
        assets[postUrl] = loader.content; 
        var dispatcher:EventDispatcher = new EventDispatcher(); 
        dispatcher.dispatchEvent(new CustomEvent(CustomEvent.LOAD_COMPLETE, assets[postUrl])); 
       }, false, 0, true); 
      } 
     } 
    } 
} 

然後，我嘗試以下方法：

var asset:AssetManager = AssetManager.load("ships/" + graphicId + ".gif"); 
      asset.addEventListener(CustomEvent.LOAD_COMPLETE, onShipAssetComplete, false, 0, true); 

，但得到的錯誤，「undefin ed方法addEventListener通過類型靜態AssetManager的引用「（粗略翻譯）。

Answer 1

你可以添加一個靜態對象（用作與URL的字典資產鍵和值資產的內容）在AssetLoader類，並在同一時間繼續使用在你使用它的方式類馬上。

private static var assets:Object = {}; 

不同之處在於如果之前已請求過內容的URL，那麼您的類將需要檢查該靜態對象。如果有，立即發送完整的事件。如果沒有，請遵循正常的例程，並且不要忘記使用新加載的資源填充靜態對象。

更新：

這是我的意思一個簡單的例子。我沒有時間來測試這個，但它應該工作。

注意： 您必須調用您創建的AssetLoader實例的loadAsset（）方法才能實際加載資產。這與我們正在擴展的Loader類的工作方式一致。

你應該總是添加所有事件偵聽器之前調用loadAsset（）方法。在你的問題中，你從構造函數中調用了load（）方法，並且之後只添加Event.COMPLETE的事件偵聽器。這可能會產生奇怪的結果。

下面的代碼：

package 
{ 
    import flash.display.Loader; 
    import flash.events.Event; 
    import flash.net.URLRequest; 


    public class AssetLoader extends Loader 
    { 
    private static const BASE_URL:String = 'http://test.com/client/assets/'; 

    public static var storedAssets:Object = {}; 

    private var assetURL:String; 
    private var urlRequest:URLRequest; 
    private var cached:Boolean = false; 


    public function AssetLoader(url:String):void 
    { 
     trace('Loading: ' + url); 
     assetURL = url; 

     if (storedAssets[assetURL] != null) 
     { 
     cached = true; 
     trace('Cached'); 
     } 
     else 
     { 
     trace('Loading uncached asset'); 
     urlRequest = new URLRequest(BASE_URL + assetURL); 
     contentLoaderInfo.addEventListener(Event.COMPLETE, OnAssetLoadComplete); 
     } 
    } 

    public function loadAsset():void 
    { 
     if (cached) 
     loadBytes(storedAssets[assetURL]); 
     else 
     load(urlRequest); 
    } 

    private function OnAssetLoadComplete(event:Event):void 
    { 
     storedAssets[assetURL] = contentLoaderInfo.bytes; 
     trace('Loaded ' + contentLoaderInfo.bytesLoaded + ' bytes'); 
    } 

    } 

} 

更新2：

這裏有一個如何使用上面的類：

var assetLdr:AssetLoader = new AssetLoader("ships/" + graphicId + ".gif"); 
assetLdr.contentLoaderInfo.addEventListener(Event.COMPLETE, onShipAssetComplete); 
assetLdr.loadAsset(); 

private function onShipAssetComplete(event:Event):void 
{ 
    var shipImage:Bitmap = Bitmap(event.target.loader.content); 
    // Do stuff with shipImage 
} 

Answer 2

也許你應該採取看看Bulk Loader。它做你想要做的事情。如果你真的想使用自定義解決方案，那將是一個很好的參考點，但爲什麼要重新發明輪子？ Tyler。

Tyler。

Answer 3

這是你的加載命令的改變來捕捉RESOURCEID

public function load(postUrl:String):* 
{ 
    var index:int; 
    if ((index = assetExists(postUrl)) != -1) 
    { 
     dispatchEvent(new CustomEvent(CustomEvent.LOAD_COMPLETE, asset[postUrl])); 
    } 
    else 
    { 
     //the asset still has to be downloaded 
     var request:URLRequest = new URLRequest(preUrl + postUrl); 
     var loader:Loader = new Loader(); 
     loader.load(request); 
     loader.contentLoaderInfo.addEventListener(Event.COMPLETE, 
     function(event:Event) 
     { 
      // NOTE: not sure on scoping here ... 
      // pretty sure you're this will be the Loader 
      // if not just read it off the event like you were before 
      assets[postUrl] = content; 
      dispatchEvent(new CustomEvent(CustomEvent.LOAD_COMPLETE, asset[postUrl])); 
     }, false, 0, true); 
    } 
} 

/* In a new file */ 
public class CustomEvent extends Event 
{ 
    public static const LOAD_COMPLETE:String = "CustomEvent_LoadComplete"; 

    // If you know the type you should use it (e.g. Sprite/DisplayObject) 
    public var content:*; 

    public function CustomEvent(type:String, _content:*) 
    { 
     content = _content; 
     super(type); 
    } 
} 

注意：當你寫一個事件，你的後代也應該覆蓋toString和clone方法。我也欺騙了構造函數，因爲你可能想通過弱引用和類似的東西。