如何在xslt 2.0中使用ends-with？

Question

我正在嘗試在xslt中使用ends-with來返回任何值。例如：我這個XML：

<BOOKS> 
    <BOOK> 
     <TITLE>title1</TITLE> 
     <ISSN>12313213</ISSN> 
    </BOOK> 
    <BOOK> 
     <TITLE>title2</TITLE> 
     <ISSN>67895776</ISSN> 
    </BOOK> 
    <BOOK> 
     <TITLE>title3</TITLE> 
     <ISSN>54363645</ISSN> 
    </BOOK> 
</BOOKS> 

這種靜態XML（是book.xml）：

<BOOKS> 
    <BOOK> 
     <VALUE>test title12</VALUE> 
     <PRICE>1235,23</PRICE> 
    </BOOK> 
    <BOOK> 
     <VALUE>test title1</VALUE> 
     <PRICE>345,23</PRICE> 
    </BOOK> 
</BOOKS> 

我需要驗證是否有標題XML書名。我的代碼：

<xsl:template match="/"> 
<xsl:variable name="book" select="document('file:///E:/book.xml')"/> 
<BOOKS> 
    <xsl:for-each select="$book/books/book"> 
     <xsl:variable name="value" select="VALUE"/> 
     <xsl:variable name="price" select="ESTRATO"/> 
     <xsl:for-each select="//BOOKS"> 
      <xsl:for-each select="BOOK"> 
       <xsl:if test="ends-with($value, @TITLE)"> 
        <BOOK> 
        <TITLE><xsl:value-of select="@TITLE"/></TITLE> 
        <ISSN><xsl:value-of select="$value"/></ISSN> 
        <PRICE><xsl:value-of select="$price"/></PRICE> 
        </BOOK> 
       </xsl:if> 
      </xsl:for-each> 
     </xsl:for-each> 
    </xsl:for-each> 
</BOOKS>  
</xsl:template> 

我希望在書籍標題結束時返回 - 在xml書籍的標記VALUE中。誰能幫我？謝謝。

我試圖用這樣的東西How to use contains in xslt?但沒有奏效。

Answer 1

你的問題並不完全清楚。我認爲你想要做這樣的事情：

XSLT 2.0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 

<xsl:param name="book" select="document('file:///E:/book.xml')"/> 

<xsl:template match="/BOOKS"> 
    <BOOKS> 
     <xsl:for-each select="BOOK"> 
      <BOOK> 
       <xsl:copy-of select="TITLE | ISSN"/> 
       <PRICE> 
        <xsl:value-of select="$book/BOOKS/BOOK[ends-with(VALUE, current()/TITLE)]/PRICE"/> 
       </PRICE> 
      </BOOK> 
     </xsl:for-each> 
    </BOOKS>  
</xsl:template> 

</xsl:stylesheet> 

---

注意XML是大小寫敏感的：book不匹配/選擇BOOK。