如何響應Delphi中對象屬性字段的變化

Question

在Delphi 7中，從TGraphicControl下降一個新組件，並添加一個TFont屬性，實現paint方法以使用TFont屬性編寫一些字符串。安裝組件。

在設計時，當您使用屬性對話框更改TFont屬性時，它將立即反映在您的組件中。但是，如果更改TFont的各個屬性（如Color或Size），則只有在將鼠標懸停在其上後，纔會重新繪製組件。

如何正確處理對象屬性字段中的更改？

Answer 1

將事件處理程序分配給TFont.OnChange事件。在處理程序中，您可以使用Invalidate()來觸發重繪。例如：

type 
    TMyControl = class(TGraphicControl) 
    private 
    FMyFont: TFont; 
    procedure MyFontChanged(Sender: TObject); 
    procedure SetMyFont(Value: TFont); 
    protected 
    procedure Paint; override; 
    public 
    constructor Create(AOwner: TComponent); override; 
    destructor Destroy; override; 
    published 
    property MyFont: TFont read FMyFont write SetMyFont; 
    end; 

constructor TMyControl.Create(AOwner: TComponent); 
begin 
    inherited; 
    FMyFont := TFont.Create; 
    FMyFont.OnChange := MyFontChanged; 
end; 

destructor TMyControl.Destroy; 
begin 
    FMyFont.Free; 
    inherited; 
end; 

procedure TMyControl.MyFontChanged(Sender: TObject); 
begin 
    Invalidate; 
end; 

procedure TMyControl.SetMyFont(Value: TFont); 
begin 
    FMyFont.Assign(Value); 
end; 

procedure TMyControl.Paint; 
begin 
    // use MyFont as needed... 
end;