wmic輸出差異cmd和批次..爲什麼？

Question

這裏是我不明白

我在cmd中執行以下命令的問題（WIN7）：

>wmic netuse where "LocalName="Z:"" get UserName /value 

輸出是美好如下：

UserName=ASI\kote 

（有在這個命令輸出的頂部和底部有2-3條空白行，這裏不能以類型格式顯示）

現在，我想運行這個命令在批處理腳本並獲取其輸出。因此，這裏是我的一樣簡單的批處理代碼：

@setlocal EnableDelayedExpansion 
@echo off 
for /f "tokens=1,2,3,4,5,6,7,8 delims=," %%a in ("X:,Y:,Z:") do (
    echo %%a,%%b,%%c 
    set currDrive=%%c 
    echo wmic netuse where "LocalName="!currDrive!"" get UserName /value 
    for /f "tokens=1,2,3,4,5,6,7,8 delims=*" %%a in ('wmic netuse where "LocalName="!currDrive!"" get UserName ^/value') do (
     echo %%a,%%b,"%%c" 
     if "%%a"=="UserName" (
      set mappedDriveUser=%%c 
      echo ===="mappedDriveUser!" 
      echo org"%%c" 
      rem set mappedDriveUser=!mappedDriveUser:^ =! 
      rem echo ====!mappedDriveUser! 
      rem echo Drive !currDrive! is connected through user !mappedDriveUser! 
     ) else (
      rem donothing 
     ) 
    ) 
) 
echo end 

這裏是批量輸出我得到：

X:,Y:,Z: 
wmic netuse where "LocalName="Z:"" get UserName /value 
,,"" 
,,"" 
,,""Name=ASI\kote 
,,"" 
,,"" 
,,"" 
end 

批處理輸出的變化，用戶消失了，實際VAR是走出來的「」 。我相信它應該進入雙引號 我需要了解相同。 此外，我需要提示，以批處理腳本獲取'正確的'wmic cmd輸出 - 這是我在cmd終端中運行命令時所得到的結果。 Thnks預先

Answer 1

的wmic命令的輸出，與get的/value開關是一樣的東西（用另外的空行）

UserName=Where\Who 

如果我們使用for /f選項來標記使用=字符串作爲用於將字段名稱（標記1）與其值（標記2）分開並且僅處理具有第二標記中的數據的行的分隔符，那麼我們可以寫出類似於

@echo off 
    setlocal enableextensions disabledelayedexpansion 

    for %%d in (f: g: h:) do (
     for /f "tokens=1,* delims==" %%a in (' 
      wmic netuse where "localname='%%d'" get username ^/value 
     ') do if not "%%b"=="" (
      echo Drive %%d mapped through %%b 
     ) 
    ) 

沒有任何需要到for更換裏面的參數值存儲到變量，如果你沒有在以後使用它們，直接用替換參數

注：從wmic輸出檢索到的值通常含有結束回車。必要時可能需要額外的for命令來放棄它。

此代碼（幾乎是相同的，只是[]加）

@echo off 
    setlocal enableextensions disabledelayedexpansion 

    for %%d in (f: g: h:) do (
     for /f "tokens=1,* delims==" %%a in (' 
      wmic netuse where "localname='%%d'" get username ^/value 
     ') do if not "%%b"=="" (
      echo Drive %%d mapped through [%%b] 
     ) 
    ) 

會產生，表現出額外的回車

]rive f: mapped through [.CN=myUserName.OU=X01.O=X 
]rive g: mapped through [.CN=myUserName.OU=X01.O=X 
]rive h: mapped through [.CN=myUserName.OU=X01.O=X 

這可以用類似處理（見額外for環）

@echo off 
    setlocal enableextensions disabledelayedexpansion 

    for %%d in (f: g: h:) do (
     for /f "tokens=1,* delims==" %%a in (' 
      wmic netuse where "localname='%%d'" get username ^/value 
     ') do if not "%%b"=="" for /f "delims=" %%c in ("%%b") do (
      echo Drive %%d mapped through [%%c] 
     ) 
    ) 

生成

Drive f: mapped through [.CN=myUserName.OU=X01.O=X] 
Drive g: mapped through [.CN=myUserName.OU=X01.O=X] 
Drive h: mapped through [.CN=myUserName.OU=X01.O=X]