使用XSLT將標籤換成標籤

Question

如何在XSLT中將單個標籤（或任何標籤）包裹在單個單詞中？我正在使用XSLT1，但似乎每次嘗試時都會卡住。

從本質上講，我想在一個段落通過（或文本字符串）：

<p>This is my text!</p> 

和包裹，像這樣的每個單詞，並保留每個單詞之間的空格和標點符號：

<p><span class="word-1">This</span> <span class="word-2">is</span> <span class="word-3">my</span> <span class="word-4">text!</span> 

這主要是爲了表達的目的，我很感激任何幫助

Answer 1

這個樣式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:param name="pSeparators">&#xA;&#x9;&#x20;,.;:?!()'"</xsl:param> 
    <xsl:template match="node()|@*"> 
     <xsl:copy> 
      <xsl:apply-templates select="node()|@*"/> 
     </xsl:copy> 
    </xsl:template> 
    <xsl:template match="p/text()" name="tokenize"> 
     <xsl:param name="pString" select="."/> 
     <xsl:param name="pMask" 
        select="translate(.,translate(.,$pSeparators,''),'')"/> 
     <xsl:param name="pCount" select="1"/> 
     <xsl:choose> 
      <xsl:when test="not($pString)"/> 
      <xsl:when test="$pMask"> 
       <xsl:variable name="vSeparator" 
           select="substring($pMask,1,1)"/> 
       <xsl:variable name="vString" 
           select="substring-before($pString,$vSeparator)"/> 
       <xsl:call-template name="tokenize"> 
        <xsl:with-param name="pString" select="$vString"/> 
        <xsl:with-param name="pMask"/> 
        <xsl:with-param name="pCount" select="$pCount"/> 
       </xsl:call-template> 
       <xsl:value-of select="$vSeparator"/> 
       <xsl:call-template name="tokenize"> 
        <xsl:with-param name="pString" 
           select="substring-after($pString,$vSeparator)"/> 
        <xsl:with-param name="pMask" 
            select="substring($pMask,2)"/> 
        <xsl:with-param name="pCount" 
            select="$pCount + boolean($vString)"/> 
       </xsl:call-template> 
      </xsl:when> 
      <xsl:otherwise> 
       <span class="word-{$pCount}"> 
        <xsl:value-of select="$pString"/> 
       </span> 
      </xsl:otherwise> 
     </xsl:choose> 
    </xsl:template> 
</xsl:stylesheet> 

輸出：

<p><span class="word-1">This</span> <span class="word-2">is</span> <span class="word-3">my</span> <span class="word-4">text</span>!</p> 

注意：令牌化的多個分隔符。 編輯：更好的名字。將空白字符添加到分隔符序列。

Answer 2

一個簡單的遞歸命名模板應該做的竅門：

<xsl:template name="wordsInTags"> 
     <xsl:param name="text" 
       select="."/> 
     <xsl:param name="index" 
       select="1"/> 
     <xsl:choose> 
     <xsl:when test="contains($text, ' ')"> 
      <span class="word-{$index}"> 
      <xsl:value-of select="substring-before($text, ' ')"/> 
      </span> 
      <xsl:text> </xsl:text> 
      <xsl:call-template name="wordsInTags"> 
      <xsl:with-param name="text"> 
       <xsl:value-of select="substring-after($text, ' ')"/> 
      </xsl:with-param> 
      <xsl:with-param name="index"> 
       <xsl:value-of select="$index + 1"/> 
      </xsl:with-param> 
      </xsl:call-template> 
     </xsl:when> 
     <xsl:otherwise> 
      <span class="word-{$index}"> 
      <xsl:value-of select="$text"/> 
      </span> 
     </xsl:otherwise> 
     </xsl:choose> 
    </xsl:template> 

，然後簡單地調用它在其中的話需要被包裝的元素：

<xsl:template match="p"> 
     <p> 
     <xsl:call-template name="wordsInTags"/> 
     </p> 
    </xsl:template> 

拋出此一起真正的快，所以它可能需要一些更多的工作，但是這應該讓你開始。