OpenGL：調試「單通線框渲染」

Question

我試圖實現「單通線框渲染」這個文件，這看起來很簡單，但它給了我所期望的厚度，黑暗的值。

該文件沒有給出確切的代碼來找出高度，所以我做了它，因爲我認爲合適。代碼應該將三個頂點投影到視口空間中，獲取它們的「高度」並將它們發送給片段着色器。

片段着色器確定最近邊緣的距離並生成edgeIntensity。我不確定我應該怎樣處理這個值，但是因爲它應該在[0,1]之間進行縮放，所以我將反轉與我的輸出顏色相乘，但它非常弱。

我有幾個問題，我不確定在論文中提到。首先，應該用2D而不是3D來計算海拔高度？其次，他們使用DirectX功能，DirectX具有不同的視口空間z範圍，是否正確？這很重要嗎？我將視出口高度距離乘以視口空間座標的w值，因爲他們建議對透視投影進行校正。

image trying to correct for perspective projection

no correction (not premultiplying by w-value)

非校正的圖像好像還沒有修正的更遠，面對的側面透視清晰的問題，但角度校正一個具有非常弱的值。

任何人都可以看到我的代碼有什麼問題，或者如何從這裏進行調試？

在GLSL我的頂點代碼...

float altitude(in vec3 a, in vec3 b, in vec3 c) { // for an ABC triangle 
    vec3 ba = a - b; 
    vec3 bc = c - b; 
    vec3 ba_onto_bc = dot(ba,bc) * bc; 
    return(length(ba - ba_onto_bc)); 
} 

in vec3 vertex; // incoming vertex 
in vec3 v2; // first neighbor (CCW) 
in vec3 v3; // second neighbor (CCW) 
in vec4 color; 
in vec3 normal; 
varying vec3 worldPos; 
varying vec3 worldNormal; 
varying vec3 altitudes; 
uniform mat4 objToWorld; 
uniform mat4 cameraPV; 
uniform mat4 normalToWorld; 
void main() { 
    worldPos = (objToWorld * vec4(vertex,1.0)).xyz; 
    worldNormal = (normalToWorld * vec4(normal,1.0)).xyz; 
    //worldNormal = normal; 
    gl_Position = cameraPV * objToWorld * vec4(vertex,1.0); 
    // also put the neighboring polygons in viewport space 
    vec4 vv1 = gl_Position; 
    vec4 vv2 = cameraPV * objToWorld * vec4(v2,1.0); 
    vec4 vv3 = cameraPV * objToWorld * vec4(v3,1.0); 
    altitudes = vec3(vv1.w * altitude(vv1.xyz,vv2.xyz,vv3.xyz), 
        vv2.w * altitude(vv2.xyz,vv3.xyz,vv1.xyz), 
        vv3.w * altitude(vv3.xyz,vv1.xyz,vv2.xyz)); 
    gl_FrontColor = color; 
} 

和我的片段代碼...

varying vec3 worldPos; 
varying vec3 worldNormal; 
varying vec3 altitudes; 
uniform vec3 cameraPos; 
uniform vec3 lightDir; 
uniform vec4 singleColor; 
uniform float isSingleColor; 
void main() { 
    // determine frag distance to closest edge 
    float d = min(min(altitudes.x, altitudes.y), altitudes.z); 
    float edgeIntensity = exp2(-2.0*d*d); 
    vec3 L = lightDir; 
    vec3 V = normalize(cameraPos - worldPos); 
    vec3 N = normalize(worldNormal); 
    vec3 H = normalize(L+V); 
    //vec4 color = singleColor; 
    vec4 color = isSingleColor*singleColor + (1.0-isSingleColor)*gl_Color; 
    //vec4 color = gl_Color; 
    float amb = 0.6; 
    vec4 ambient = color * amb; 
    vec4 diffuse = color * (1.0 - amb) * max(dot(L, N), 0.0); 
    vec4 specular = vec4(0.0); 
    gl_FragColor = (edgeIntensity * vec4(0.0)) + ((1.0-edgeIntensity) * vec4(ambient + diffuse + specular)); 
} 

Answer 1

第一，你的函數的高度（）是有缺陷的，ba_onto_bc計算因爲bc不是單位長度（要麼將bc歸一化，要麼將ba_onto_bc除以長度平方的點（bc，bc） - 這樣可以節省計算平方根的時間）。

如果您想要恆定厚度的邊緣，則應該用2D來計算海拔高度;如果您想要透視正確的邊緣，則用3D來計算海拔。使用重心座標作爲單獨的頂點屬性（即，三角形的頂點0將得到（1 0 0），第二頂點（0 1 0）和最後一個頂點（0 0））將會容易得多， 1））。在片段着色器中，您將計算最小值並使用step（）或smoothstep（）來計算邊緣。

這隻需要1個屬性而不是當前的兩個，它也可以避免在頂點着色器中計算高度的需要（儘管如果您想對預測重心的座標進行預分級，但離線計算）。它也應該是非常快速的工作，所以這將是一個很好的起點，以達到預期的行爲。

Answer 2

我已經實現豬的想法，結果是完美的，這裏是我的截圖：

struct MYBUFFEREDVERTEX { 
    float x, y, z; 
    float nx, ny, nz; 
    float u, v; 
    float bx, by, bz; 
}; 

const MYBUFFEREDVERTEX g_vertex_buffer_data[] = { 
    -1.0f, -1.0f, 0.0f, 
    0.0f, 0.0f, 1.0f, 
    0.0f, 0.0f, 
    1.0f, 0.0f, 0.0f, 

    1.0f, -1.0f, 0.0f, 
    0.0f, 0.0f, 1.0f, 
    1.0f, 0.0f, 
    0.0f, 1.0f, 0.0f, 

    -1.0f, 1.0f, 0.0f, 
    0.0f, 0.0f, 1.0f, 
    0.0f, 1.0f, 
    0.0f, 0.0f, 1.0f, 

    1.0f, 1.0f, 0.0f, 
    0.0f, 0.0f, 1.0f, 
    1.0f, 1.0f, 
    1.0f, 0.0f, 0.0f, 
}; 

glDrawArrays(GL_TRIANGLE_STRIP, 0, 4); 

頂點着色器：

#ifdef GL_ES 
// Set default precision to medium 
precision mediump int; 
precision mediump float; 
#endif 

uniform mat4 u_mvp_matrix; 
uniform vec3 u_light_direction; 

attribute vec3 a_position; 
attribute vec3 a_normal; 
attribute vec2 a_texcoord; 
attribute vec3 a_barycentric; 

varying vec2 v_texcoord; 
varying float v_light_intensity; 
varying vec3 v_barycentric; 

void main() 
{ 
    // Calculate vertex position in screen space 
    gl_Position = u_mvp_matrix * vec4(a_position, 1.0); 
    // calculate light intensity, range of 0.3 ~ 1.0 
    v_light_intensity = max(dot(u_light_direction, a_normal), 0.3); 
    // Pass texture coordinate to fragment shader 
    v_texcoord = a_texcoord; 
    // Pass bary centric to fragment shader 
    v_barycentric = a_barycentric; 
} 

片段着色器：

#ifdef GL_ES 
// Set default precision to medium 
precision mediump int; 
precision mediump float; 
#endif 

uniform sampler2D u_texture; 

varying vec2 v_texcoord; 
varying float v_light_intensity; 
varying vec3 v_barycentric; 

void main() 
{ 
    float min_dist = min(min(v_barycentric.x, v_barycentric.y), v_barycentric.z); 
    float edgeIntensity = 1.0 - step(0.005, min_dist); 
    // Set diffuse color from texture 
    vec4 diffuse = texture2D(u_texture, v_texcoord) * vec4(vec3(v_light_intensity), 1.0); 
    gl_FragColor = edgeIntensity * vec4(0.0, 1.0, 1.0, 1.0) + (1.0 - edgeIntensity) * diffuse; 
}