VBA集合：密鑰列表

Question

在向VBA集合添加一些值之後，有沒有辦法保留所有密鑰的列表？

例如

Dim coll as new Collection 
Dim str1, str2, str3 
str1="first string" 
str2="second string" 
str3="third string" 
coll.add str1, "first key" 
coll.add str2, "second key" 
coll.add str3, "third key" 

我知道如何保留字符串列表：再次

first string 
second string 
third string 

：有什麼辦法留住鑰匙？

first key 
second key 
third key 

注：我使用VBA通過AutoCAD 2007的

Answer 1

我不認爲可能與香草集合，沒有一個獨立的存儲陣列中的鍵值。最簡單的替代方法是添加對Microsoft腳本運行時的引用&而不是使用更強大的字典;

Dim coll As New Dictionary 
... 
Dim K As Variant 
For Each K In coll.Keys 
    debug.print "Key: " & K , "Value: " & coll.Item(K) 
Next 

Answer 2

如果您打算使用默認VB6 Collection，那麼你可以做最簡單的就是：

col1.add array("first key", "first string"), "first key" 
col1.add array("second key", "second string"), "second key" 
col1.add array("third key", "third string"), "third key" 

然後你可以列出所有值：

Dim i As Variant 

For Each i In col1 
    Debug.Print i(1) 
Next 

個或所有密鑰：

Dim i As Variant 

For Each i In col1 
    Debug.Print i(0) 
Next 

Answer 3

另一種解決方案是將密鑰存儲在單獨的收集：

'Initialise these somewhere. 
Dim Keys As Collection, Values As Collection 

'Add types for K and V as necessary. 
Sub Add(K, V) 
Keys.Add K 
Values.Add V, K 
End Sub 

您可以維護的鍵和值，這可能是有用的，有時單獨的排序順序。

Answer 4

您可以創建一個小類來保存鍵和值，然後將該類的對象存儲在集合中。

類KEYVALUE：

Public key As String 
Public value As String 
Public Sub Init(k As String, v As String) 
    key = k 
    value = v 
End Sub 

然後使用它：

Public Sub Test() 
    Dim col As Collection, kv As KeyValue 
    Set col = New Collection 
    Store col, "first key", "first string" 
    Store col, "second key", "second string" 
    Store col, "third key", "third string" 
    For Each kv In col 
     Debug.Print kv.key, kv.value 
    Next kv 
End Sub 

Private Sub Store(col As Collection, k As String, v As String) 
    If (Contains(col, k)) Then 
     Set kv = col(k) 
     kv.value = v 
    Else 
     Set kv = New KeyValue 
     kv.Init k, v 
     col.Add kv, k 
    End If 
End Sub 

Private Function Contains(col As Collection, key As String) As Boolean 
    On Error GoTo NotFound 
    Dim itm As Object 
    Set itm = col(key) 
    Contains = True 
MyExit: 
    Exit Function 
NotFound: 
    Contains = False 
    Resume MyExit 
End Function 

這是當然類似於字典建議，除沒有任何外部依賴性。如果你想存儲更多的信息，這個類可以根據需要變得更加複雜。

Answer 5

麻煩的是，對於大型數據集，集合執行方式比任何字典更好...