xsl：xml元素的平均值

Question

你能幫我調試一下找出錯誤的來源嗎？
我想找到XML中的兩個元素的平均值，並將其添加到最終的XML。
我可能會做一些根本性的錯誤，請你幫忙。

在此先感謝。 fornula S =（C + d）/ 2

xml文檔

<?xml version="1.0" encoding="UTF-8"?> 
<top> 
    <Results> 
     <a>no</a> 
     <b>12</b> 
     <c>12</c> 
     <d>9</d> 
    </Results> 
    <Results> 
     <a>yes</a> 
     <b>8</b> 
     <c>50</c> 
     <d>12</d> 
    </Results> 
    <Results> 
     <a>no</a> 
     <b>6</b> 
     <c>55</c> 
     <d>56</d> 
    </Results> 
    <Results> 
     <a>yes</a> 
     <b>23</b> 
     <c>32</c> 
     <d>34</d> 
    </Results> 
</top> 

XSL文件

<xsl:output method="xml" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="@* | node()" name="identity"> 
    <xsl:copy> 
    <xsl:apply-templates select="@* | node()"/> 
    </xsl:copy> 
</xsl:template> 

    <xsl:variable name="x" select="//c"/> 
    <xsl:variable name="y" select="//d"/> 

<xsl:template match="b"> 
    <xsl:call-template name="identity"/> 
    <s> 
    <xsl:value-of select="($x + $y) div 2"/> 
    </s> 
</xsl:template> 
</xsl:stylesheet> 

期望輸出

<?xml version="1.0"?> 
<top> 
    <Results> 
    <a>no</a> 
    <b>12</b> 
    <s>10.5</s> 
    <c>12</c> 
    <d>9</d> 
    </Results> 
    <Results> 
    <a>yes</a> 
    <b>8</b> 
    <s>31</s> 
    <c>50</c> 
    <d>12</d> 
    </Results> 
    <Results> 
    <a>no</a> 
    <b>6</b> 
    <s>55.5</s> 
    <c>55</c> 
    <d>56</d> 
    </Results> 
    <Results> 
    <a>yes</a> 
    <b>23</b> 
    <s>33</s> 
    <c>32</c> 
    <d>34</d> 
    </Results> 
</top> 

上面的代碼和輸入是一個模擬th的例子e真實數據集。因此，我正在尋找識別代碼中的錯誤，這是更大代碼的一部分。 任何幫助將高度appriciated。

Answer 1

你在想太複雜。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" indent="yes"/> 
    <xsl:strip-space elements="*"/> 

    <xsl:template match="@* | node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@* | node()"/> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="Results"> 
    <xsl:copy> 
     <xsl:apply-templates select="@* | node()" /> 
     <s><xsl:value-of select="(sum(c) + sum(d)) div 2" /></s> 
    </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet> 

如果您在<Results>元素堅持的孩子才能上，使用

<xsl:template match="Results"> 
    <xsl:copy> 
    <xsl:apply-templates select="@* | a | b" /> 
    <s><xsl:value-of select="(sum(c) + sum(d)) div 2" /></s> 
    <xsl:apply-templates select="c | d" /> 
    </xsl:copy> 
</xsl:template> 

如果永遠只可能是一個<c>和<d>在一組，這已經足夠了：

<xsl:value-of select="(c + d) div 2" /> 

Answer 2

我想我已經發現了一種解決報告問題的方法。

問候

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

<xsl:output method="xml" indent="yes"/> 
<xsl:strip-space elements="*"/> 


<xsl:template match="@* | node()" name="identity"> 
    <xsl:copy> 
    <xsl:apply-templates select="@* | node()"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="b"> 
    <xsl:call-template name="identity"/> 
    <xsl:variable name="x" select="../c"/> 
    <xsl:variable name="y" select="../d"/> 
    <s><xsl:value-of select="($x + $y) div 2"/></s> 
</xsl:template> 
</xsl:stylesheet>