如何在excel中操縱字符串 - VB？

Question

我想知道是否有人能告訴我如何在Excel-VB中從以下字符串推斷'http://www.nbc.com/xyz'和'我喜歡這個節目'。

感謝

<a href="http://www.nbc.com/xyz" >I love this show</a><IMG border=0 width=1 height=1 src="http://ad.linksynergy.com/fs-bin/show?id=Loe5O5QVFig&bids=261463.100016851&type=3&subid=0" > 

Answer 1

一旦方法是使用正則表達式。另一種方式是使用分割到各個分隔符分割的字符串例如

Option Explicit 

Sub splitMethod() 
Dim Str As String 

    Str = Sheet1.Range("A1").Value 
    Debug.Print Split(Str, """")(1) 
    Debug.Print Split(Split(Str, ">")(1), "</a")(0) 

End Sub 

Sub RegexMethod() 
Dim Str As String 
Dim oRegex As Object 
Dim regexArr As Object 
Dim rItem As Object 

    'Assumes Sheet1.Range("A1").Value holds example string 
    Str = Sheet1.Range("A1").Value 

    Set oRegex = CreateObject("vbscript.regexp") 
    With oRegex 
     .Global = True 
     .Pattern = "(href=""|>)(.+?)(""|</a>)" 
     Set regexArr = .Execute(Str) 

     'No lookbehind so replace unwanted chars 
     .Pattern = "(href=""|>|""|</a>)" 
     For Each rItem In regexArr 
      Debug.Print .Replace(rItem, vbNullString) 
     Next rItem 
    End With 
End Sub 

'Output: 
'http://www.nbc.com/xyz 
'I love this show 

此匹配字符串，"或</a>在與任何字符的字符串的末尾開始href="或>（除了\ n換行）在之間(.+?)

Answer 2

Sub Tester() 
    '### add a reference to "Microsoft HTML Object Library" ### 
    Dim odoc As New MSHTML.HTMLDocument 
    Dim el As Object 
    Dim txt As String 

    txt = "<a href=""http://www.nbc.com/xyz"" >I love this show</a>" & _ 
     "<IMG border=0 width=1 height=1 " & _ 
     "src=""http://ad.linksynergy.com/fs-bin/show?" & _ 
     "id=Loe5O5QVFig&bids=261463.100016851&type=3&subid=0"" >" 

    odoc.body.innerHTML = txt 

    Set el = odoc.getElementsByTagName("a")(0) 
    Debug.Print el.innerText 
    Debug.Print el.href 

End Sub