M-q的反函數，不完整段落函數

Question

是否有與相反的M-q，某種unfill-paragraph-function？

如果我有撤消數據，那當然很容易。我所要求的只是在剛剛從磁盤讀取文件之後，將段落中的行合併爲一個長整行的能力。這樣就可以將文本粘貼到期望每個段落只有一個換行符的表單（網頁表單等）中。

在過去，我關閉了auto-fill，創建了一個宏來刪除一個EOL並移動到下一行，並重復應用它，但這會讓人很累。

Answer 1

Here's the answer。總之：

(defun unfill-paragraph() 
    "Replace newline chars in current paragraph by single spaces. 
This command does the reverse of `fill-paragraph'." 
    (interactive) 
    (let ((fill-column 90002000)) 
    (fill-paragraph nil))) 

(defun unfill-region (start end) 
    "Replace newline chars in region by single spaces. 
This command does the reverse of `fill-region'." 
    (interactive "r") 
    (let ((fill-column 90002000)) 
    (fill-region start end))) 

更新：我已經打包這件事here它可以從Marmalade或Melpa安裝。

Answer 2

另請參閱M- ^（刪除縮進）。

它將當前行連接到上一行，所以如果您從段落的最後一行開始，您可以繼續按M- ^，直到所有行都合併爲止。

Answer 3

也看到這個帖子

http://blog.chrislowis.co.uk/2010/03/03/unfill-region-emacs.html

，其中提到了非常有用的延繩釣模式。

Answer 4

我第一次使用@ sanityinc的解決方案一段時間，直到我來到Stefan Monnier's Unfill Paragraph in EmacsWiki。看起來更加強大

;;; Stefan Monnier <foo at acm.org>. It is the opposite of fill-paragraph  
(defun unfill-paragraph (&optional region) 
    "Takes a multi-line paragraph and makes it into a single line of text." 
    (interactive (progn (barf-if-buffer-read-only) '(t))) 
    (let ((fill-column (point-max)) 
     ;; This would override `fill-column' if it's an integer. 
     (emacs-lisp-docstring-fill-column t)) 
    (fill-paragraph nil region))) 

;; Handy key definition 
(define-key global-map "\M-Q" 'unfill-paragraph) 

(defun unfill-region (beg end) 
    "Unfill the region, joining text paragraphs into a single 
logical line. This is useful, e.g., for use with 
`visual-line-mode'." 
    (interactive "*r") 
    (let ((fill-column (point-max))) 
    (fill-region beg end))) 

;; Handy key definition 
(define-key global-map "\C-\M-Q" 'unfill-region) 

鍵綁定使命令變得更容易。