SAS Proc Gchart堆積區域圖

Question

您好我在SAS中創建圖表時遇到問題。我的數據如下： Date，comp_1，comp_2，comp_3，total_value。我的數據按日期排序。變量comp_代表公司在特定數據下的價值。這是我的時刻代碼：

proc gplot data=dev2.Actionfinal2; 
    plot (comp_1 comp_2 comp_3)*date 
     /overlay areas=3 vaxis=0 to 100000 by 20000; 
    symbol1 i=join v= cv= ci=red; 
    symbol2 i=join v= cv= ci=blue; 
    symbol3 i=join v= cv= ci=green; 
run; 
quit; 

這個圖表告訴我覆蓋在3家公司的價值，但我希望他們堆疊，所以我可以看到公司的每個日期的總價值。我需要重新格式化我的數據，我可以使用什麼選項？

Answer 1

您將需要創建一個新變量，其中包含三個「comp」變量的聚合值。有一個很好的例子見this SAS usage note。這應該讓你開始並歡迎來到StackOverflow！

更新：我想我更好地理解這個問題：您需要對數據進行非規格化（將列轉化爲觀察值）。所以試試這個：

data test(keep=company value date); 
    set dev2.Actionfinal2; 
    company = 1; value = comp_1; output; 
    company = 2; value = comp_2; output; 
    company = 3; value = comp_3; output; 
run; 

proc sort data=test; 
    by date company; 
run; 

data test2; 
    set test; 
     by date; 
    if first.date then new_y=0; 
    new_y + value; 
run; 

symbol1 i=join v= cv= ci=red; 
symbol2 i=join v= cv= ci=blue; 
symbol3 i=join v= cv= ci=green; 

proc gplot data=test2; 
    plot new_y*date=company 
     /areas=3 vaxis=0 to 100000 by 20000; 
run; 
quit;