簡單的XSLT屬性加成

Question

我希望做一些很簡單的XSLT我的XML文檔，它具有如下的結構：

<XML> 
    <TAG1 attribute1="A"> 
     <IRRELEVANT /> 
     <TAG2 attribute2="B" attribute3="34" /> 
    </TAG1> 
</XML> 

，我試圖做一個XSLT其執行以下操作：

1. 複製一切
2. 如果TAG2 @ ATTRIBUTE1 = 「a」 和TAG2 @ attribute2 = 「B」 並沒有TAG2 @ attribute4，然後添加@ attribute4到TAG2和有它的價值是TAG2 @ attribute3的價值

我不成功的嘗試如下。我收到的錯誤是 「xsl：attribute：如果子元素已添加到元素，則無法向元素添加屬性。」

謝謝！

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:param name="newDocumentHeader" /> 

    <!-- copy idiom copying ALL nodes --> 
    <xsl:template match="node()|@*"> 
     <xsl:copy> 
     <xsl:apply-templates select="node() | @*" /> 
     </xsl:copy> 
    </xsl:template> 

    <!-- override for special case --> 
    <xsl:template match="TAG1[@attribute1='A']/TAG2[@attribute2='B'][not(@attribute4)]"> 
     <xsl:attribute name="attribute4"> 
     <xsl:value-of select="@attribute3" /> 
     </xsl:attribute> 
    </xsl:template> 

</xsl:stylesheet> 

Answer 1

什麼是你的XSLT代碼缺少僅僅是匹配的元素的副本。然而，你的情況（簡單的XSLT屬性加成），你可以直接覆蓋節點attribute3：

<xsl:template match="TAG1[@attribute1='A'] 
     /TAG2[@attribute2='B' and not(@attribute4)] 
      /@attribute3"> 
    <xsl:copy-of select="."/> 
    <xsl:attribute name="attribute4"> 
     <xsl:value-of select="." /> 
    </xsl:attribute> 
</xsl:template> 

集成在當前的變換，產生：

<XML> 
    <TAG1 attribute1="A"> 
     <IRRELEVANT></IRRELEVANT> 
     <TAG2 attribute2="B" attribute3="34" attribute4="34"></TAG2> 
    </TAG1> 
</XML> 

Answer 2

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

    <xsl:template match="node() | @*"> 
     <xsl:copy> 
      <xsl:apply-templates select="node() | @*" /> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="TAG1[@attribute1 = 'A']/TAG2[@attribute2= 'B' ][not(@attribute4)]"> 
     <xsl:copy> 
      <xsl:attribute name="attribute4"> 
       <xsl:value-of select="@attribute3" /> 
      </xsl:attribute> 
      <xsl:apply-templates select="node() | @*"/> 
     </xsl:copy> 

    </xsl:template> 

</xsl:stylesheet> 

結果：

<XML> 
    <TAG1 attribute1="A"> 
     <IRRELEVANT /> 
     <TAG2 attribute4="34" attribute2="B" attribute3="34" /> 
    </TAG1> 
</XML>