如何確定抽象方法是否實現？

Question

我正在使用一個非常大的delphi第三方庫，沒有源代碼，這個庫有幾個抽象方法的類。我需要在運行時確定何時由Descendant類實現abtract方法，以避免EAbstractError: Abstract Error並向用戶顯示自定義消息或使用其他類。

例如在此代碼中我想在運行時檢查MyAbstractMethod是否已實施。

type 
    TMyBaseClass = class 
    public 
    procedure MyAbstractMethod; virtual; abstract; 
    end; 

    TDescendantBase = class(TMyBaseClass) 
    public 
    end; 

    TChild = class(TDescendantBase) 
    public 
    procedure MyAbstractMethod; override; 
    end; 

    TChild2 = class(TDescendantBase) 
    end; 

我如何確定抽象方法是否在運行時的Descendant類中實現？

Answer 1

您可以使用Rtti，GetDeclaredMethods函數獲取在反射（當前）類型中聲明的所有方法的列表。所以你可以檢查方法是否存在於這個函數返回的列表中。

function MethodIsImplemented(const AClass:TClass;MethodName : string): Boolean; 
var 
    m : TRttiMethod; 
begin 
    Result := False; 
    for m in TRttiContext.Create.GetType(AClass.ClassInfo).GetDeclaredMethods do 
    begin 
    Result := CompareText(m.Name, MethodName)=0; 
    if Result then 
    break; 
    end; 
end; 

，或者你可以比較TRttiMethod的Parent.Name財產，檢查是否匹配當前的類名。

function MethodIsImplemented(const AClass:TClass;MethodName : string): Boolean; 
var 
    m : TRttiMethod; 
begin 
    Result := False; 
    m:=TRttiContext.Create.GetType(AClass.ClassInfo).GetMethod(MethodName); 
    if m<>nil then 
    Result:=CompareText(AClass.ClassName,m.Parent.Name)=0; 
end; 

Answer 2

查看VCL源代碼中TStream.Seek()方法的實現。它會執行類似的類似於後代的重寫檢查，而不涉及TRttiContext查找，只需通過其父/子vtable條目的簡單循環即可。

Answer 3

function ImplementsAbstractMethod(AObj: TMyBaseClass): Boolean; 
type 
    TAbstractMethod = procedure of object; 
var 
    BaseClass: TClass; 
    BaseImpl, Impl: TAbstractMethod; 
begin 
    BaseClass := TMyBaseClass; 
    BaseImpl := TMyBaseClass(@BaseClass).MyAbstractMethod; 
    Impl := AObj.MyAbstractMethod; 
    Result := TMethod(Impl).Code <> TMethod(BaseImpl).Code; 
end;