複製到CUDA到設備內存CUDA

Question

的結構我新，並通過CUDA工具包文件去。在那裏我發現了一個矩陣乘法使用共享內存的例子。這裏，當從主機存儲器複製矩陣結構到設備存儲器時，只有數據元素被複制。我不明白的是其他變量如何複製到設備內存。

矩陣結構如下

typedef struct { 
    int width; 
    int height; 
    int stride; 
    float* elements; 
} Matrix; 

然後這裏是代碼示例，其中數據傳輸發生

void MatMul(const Matrix A, const Matrix B, Matrix C) 
{ 
    // Load A and B to device memory 
    Matrix d_A; 
    d_A.width = d_A.stride = A.width; d_A.height = A.height; 
    size_t size = A.width * A.height * sizeof(float); 
    cudaMalloc(&d_A.elements, size); 
    cudaMemcpy(d_A.elements, A.elements, size, 
       cudaMemcpyHostToDevice); 
    Matrix d_B; 
    d_B.width = d_B.stride = B.width; d_B.height = B.height; 
    size = B.width * B.height * sizeof(float); 
    cudaMalloc(&d_B.elements, size); 
    cudaMemcpy(d_B.elements, B.elements, size, 
    cudaMemcpyHostToDevice); 

    // Allocate C in device memory 
    Matrix d_C; 
    d_C.width = d_C.stride = C.width; d_C.height = C.height; 
    size = C.width * C.height * sizeof(float); 
    cudaMalloc(&d_C.elements, size); 

    // Invoke kernel 
    dim3 dimBlock(BLOCK_SIZE, BLOCK_SIZE); 
    dim3 dimGrid(B.width/dimBlock.x, A.height/dimBlock.y); 
    MatMulKernel<<<dimGrid, dimBlock>>>(d_A, d_B, d_C); 

    // Read C from device memory 
    cudaMemcpy(C.elements, d_C.elements, size, 
       cudaMemcpyDeviceToHost); 

    // Free device memory 
    cudaFree(d_A.elements); 
    cudaFree(d_B.elements); 
    cudaFree(d_C.elements); 
} 

這裏是什麼我不明白是怎麼寬度，步幅和高度將被複制到設備內存。因爲這裏的cudaMalloc和cudaMemcpy僅適用於元素。在理解這件事時我有沒有想過？

的籽粒代碼

__device__ float GetElement(const Matrix A, int row, int col) 
{ 
    return A.elements[row * A.stride + col]; 
} 

// Set a matrix element 
__device__ void SetElement(Matrix A, int row, int col, 
          float value) 
{ 
    A.elements[row * A.stride + col] = value; 
} 

// Get the BLOCK_SIZExBLOCK_SIZE sub-matrix Asub of A that is 
// located col sub-matrices to the right and row sub-matrices down 
// from the upper-left corner of A 
__device__ Matrix GetSubMatrix(Matrix A, int row, int col) 
{ 
    Matrix Asub; 
    Asub.width = BLOCK_SIZE; 
    Asub.height = BLOCK_SIZE; 
    Asub.stride = A.stride; 
    Asub.elements = &A.elements[A.stride * BLOCK_SIZE * row 
             + BLOCK_SIZE * col]; 
    return Asub; 
} 

矩陣乘法籽粒代碼

__global__ void MatMulKernel(Matrix A, Matrix B, Matrix C) 
{ 
    // Block row and column 
    int blockRow = blockIdx.y; 
    int blockCol = blockIdx.x; 

    // Each thread block computes one sub-matrix Csub of C 
    Matrix Csub = GetSubMatrix(C, blockRow, blockCol); 

    // Each thread computes one element of Csub 
    // by accumulating results into Cvalue 
    float Cvalue = 0; 

    // Thread row and column within Csub 
    int row = threadIdx.y; 
    int col = threadIdx.x; 

    // Loop over all the sub-matrices of A and B that are 
    // required to compute Csub 
    // Multiply each pair of sub-matrices together 
    // and accumulate the results 
    for (int m = 0; m < (A.width/BLOCK_SIZE); ++m) { 

     // Get sub-matrix Asub of A 
     Matrix Asub = GetSubMatrix(A, blockRow, m); 

     // Get sub-matrix Bsub of B 
     Matrix Bsub = GetSubMatrix(B, m, blockCol); 

     // Shared memory used to store Asub and Bsub respectively 
     __shared__ float As[BLOCK_SIZE][BLOCK_SIZE]; 
     __shared__ float Bs[BLOCK_SIZE][BLOCK_SIZE]; 

     // Load Asub and Bsub from device memory to shared memory 
     // Each thread loads one element of each sub-matrix 
     As[row][col] = GetElement(Asub, row, col); 
     Bs[row][col] = GetElement(Bsub, row, col); 

     // Synchronize to make sure the sub-matrices are loaded 
     // before starting the computation 
     __syncthreads(); 
     // Multiply Asub and Bsub together 
     for (int e = 0; e < BLOCK_SIZE; ++e) 
      Cvalue += As[row][e] * Bs[e][col]; 

     // Synchronize to make sure that the preceding 
     // computation is done before loading two new 
     // sub-matrices of A and B in the next iteration 
     __syncthreads(); 
    } 

    // Write Csub to device memory 
    // Each thread writes one element 
    SetElement(Csub, row, col, Cvalue); 
} 

Answer 1

對於那些誰不知道，我們談論的示例代碼是在這裏NVIDIA的CUDA Toolkit文檔，共享內存主題： CUDA C Programming guide : Shared memory

那麼，爲什麼這樣的工作？ 是，僅「元素」陣列上設備側利用cudaMalloc和cudaMemcpy功能發送。 是，矩陣尺寸上裝置側的內核內使用而不被顯式地複製到與cudaMemcpy設備存儲器中。

您需要以同樣的方式不考慮數組和參數。讓我解釋如何將這些值發送給內核。

1. 我們聲明上CPU側的矩陣，所有的成員都初始化
2. 我們指定的尺寸，指針仍然是未初始化
3. 我們分配和對設備側複製存儲器與API函數，該指針被初始化但它瞄準設備內存，不能像普通主機陣列一樣使用
4. 我們將矩陣作爲內核的參數。不是通過指針，而是通過價值。

這就是訣竅。完整的結構實例被給定爲一個參數，它包含：

1. 三個整數，所述矩陣
2. 的指針數組，包含矩陣數據

給予整數作爲的尺寸內核啓動中的參數顯然是可能的，並且工作正常。 給指針指向一個數組也是可能的：指針被複制，這意味着我們創建另一個指向內存中同一個區域的指針。如果我們的目標數組在主機內存上，它會導致錯誤，但由於它已經在設備端用API函數初始化，所以它工作正常。