組合（A - >也許一）和（a - > a）職能

Question

我有兩個功能：

f :: a -> Maybe a 
g :: a -> a 

我想創建這樣的功能：

h :: a -> Maybe a 

h x 
| isJust(f x) = Just (g $ fromJust(f x)) 
| otherwise = Nothing 

我該怎麼辦呢以更優雅的方式？

Answer 1

既然你已經標記爲dot-operator這個問題：

h :: a -> Maybe a 
h = fmap g . f 

有關說明：

f   ::       a -> Maybe a 
g   ::  a ->  a 
fmap g  :: Maybe a -> Maybe a 
(.)   :: (Maybe a -> Maybe a) -> (a -> Maybe a) -> (a -> Maybe a) 
(.) (fmap g) ::       (a -> Maybe a) -> (a -> Maybe a) 
fmap g . f ::           (a -> Maybe a) 
h   ::           a -> Maybe a 

注意(.)的和fmap g的類型實際上是更普遍的：

(.) :: (b -> c) -> (a -> b) -> (a -> c) 
-- b in this case is Maybe a 
-- c in this case is Maybe a 

fmap g :: Functor f => f a -> f a 
-- f in this case is Maybe 

但是，你也可以對f結果模式匹配：

h x = 
    case f x of 
    Just k -> Just (g k) 
    _  -> Nothing 

請注意，您的原始示例甚至不會編譯，因爲g的返回類型不正確。

Answer 2

爲什麼不能簡單：

h :: a -> Maybe a 
h x = fmap g (f x) 

或運營商版本：

h :: a -> Maybe a 
h x = g <$> f x 

Answer 3

有

fmap2 :: (Functor g, Functor f) => (a -> b) -> g (f a) -> g (f b) 
fmap2 = fmap . fmap 

這裏是一個有趣的方式：

h :: a -> Maybe a 
h = fmap2 g f 

fmap2 g f ~> fmap (fmap g) f ~> fmap g . f ~> \x -> fmap g (f x)

的Functor ((->) r)例如用在這裏：fmap可以用來代替(.)。