刪除行，如果第一個單元格不是數字VBA的Excel

Question

我使用下面的代碼刪除行，如果第一個單元格不是數字（文本或空白單元格）

Dim LR3 As Long, i3 As Long 
With Sheets("Productos") 
LR3 = Range("A" & Rows.Count).End(xlUp).Row 
For i3 = LR3 To 2 Step -1 
    If IsNumeric(Sheets("Productos").Range("A" & i3).Value) Then 
    Else 
    Rows(i3).Delete 
    End If 
Next i3 
End With 

LR3 2的使用，因爲第一行是一個標題行，我不希望它被刪除。我沒有看到代碼有什麼問題，甚至沒有錯誤。你看到有什麼問題嗎？這可能是一個虛假的程序？

Answer 1

我懷疑你的代碼存在問題，Sheets("Productos")不是activesheet。所以Rows(i3).Delete指的是這可能不是Sheets("Productos")

請注意，在下面的代碼中使用點的activesheet。

試試這個（久經考驗）

Sub Sample() 
    Dim LR3 As Long, i3 As Long 

    With Sheets("Productos") 
     LR3 = .Range("A" & .Rows.Count).End(xlUp).Row 

     For i3 = LR3 To 2 Step -1 
      If Not IsNumeric(.Range("A" & i3).Value) Then .Rows(i3).Delete 
     Next i3 
    End With 
End Sub 

編輯：我錯過了空白單元格的一部分，但由於吉米的帖子，我看到了。

修正代碼

Sub Sample() 
    Dim LR3 As Long, i3 As Long 

    With Sheets("Productos") 
     LR3 = .Range("A" & .Rows.Count).End(xlUp).Row 

     For i3 = LR3 To 2 Step -1 
      If Not IsNumeric(.Range("A" & i3).Value) Or _ 
      .Range("A" & i3).Value = "" Then .Rows(i3).Delete 
     Next i3 
    End With 
End Sub 

Answer 2

如果單元格爲空，則IsNumeric將返回true。你可以嘗試使用len，

Dim LR3 As Long, i3 As Long 

With Sheets("Productos") 
    LR3 = .Range("A" & .Rows.Count).End(xlUp).Row 

    For i3 = LR3 To 2 Step -1 
     If IsNumeric(.Range("A" & i3).Value) And _ 
     len(.Range("A" & i3).Value) > 0 Then 

     Else 
      .Rows(i3).Delete 
     End If 
    Next i3 
End With