代碼從NSI腳本片段：爲什麼VIProductVersion參數會覆蓋ProductVersion鍵的值？
VIProductVersion 1.2.0.0
VIAddVersionKey /LANG=${LANG_ENGLISH} FileVersion 1.1.0.0
我想設置文件版本到1.1.0.0但在文件屬性設置爲1.2.0.0。我也注意到VIProductVersion自己執行加了FileVersion鍵並設置它的值。
文檔說VIProductVersion添加產品版本但我看到的是，文件版本實際上添加。這是NSIS中的錯誤嗎？ VIAddVersionKey FileVersion的目的是什麼，如果它設置的值被覆蓋VIProductVersion設置的值？
VIAddVersionKey要求VIProductVersion調用，否則腳本不會編譯。
我使用的版本：EclipseNSIS 0.9.8; MakeNSIS 2.46。操作系統：Windows 7
版本信息資源存儲在兩個部分：
有些應用程序使用的文件版本字符串，並回落到VS_FIXEDFILEINFO :: dwFileVersion如果字符串不存在，其他應用程序只能使用VS_FIXEDFILEINFO :: dwFileVersion等
VIProductVersion "1.2.3.4"會生成一個版本頭，看起來像
1 VERSIONINFO
FILEVERSION 1,2,3,4
PRODUCTVERSION 1,2,3,4
FILEOS 0x4
FILETYPE 0x1
這通常足夠，但它不會讓您設置PRODUCTVERSION！= FILEVERSION。
我認爲這是NSIS中的一個錯誤，他們應該添加VIFileVersion命令或將VIProductVersion擴展爲VIProductVersion <productver> [filever]。
您可以在tracker上添加功能請求。
與此同時，你可能能夠解決此通過構建與packhdr過程中調用
resource hacker
編輯：
它可以與2.46在編譯時間來完成！packhdr，外部第三方工具（我是無法得到reshacker導入.RC版本資源，所以我不得不轉換爲.RES第一）和可怕的黑客：
!macro HackyVIFileVersion reshack gorcjorg fixedfilever
;http://www.angusj.com/resourcehacker/
;http://web.archive.org/web/20090918063311/http://www.jorgon.freeserve.co.uk/Gorcjorg.zip
!searchreplace HackyVIFileVersion_id "${__TIME__}" ":" ""
!define HackyVIFileVersion_cmd "$%TEMP%\nsisVIFV${HackyVIFileVersion_id}.cmd"
!appendfile "${HackyVIFileVersion_cmd}" `@echo off&setlocal ENABLEEXTENSIONS DISABLEDELAYEDEXPANSION$\n`
!appendfile "${HackyVIFileVersion_cmd}" `set eh=%TEMP%\exehead%~1.tmp$\n`
!appendfile "${HackyVIFileVersion_cmd}" `set rh=%~2$\n`
!appendfile "${HackyVIFileVersion_cmd}" `call "%rh%" -extract "%eh%", "%eh%1.rc", VersionInfo,1,$\n`
!appendfile "${HackyVIFileVersion_cmd}" `> "%eh%2.rc" echo.LANGUAGE LANG_ENGLISH, SUBLANG_ENGLISH_US $\n` ;must force lang for Gorcjorg
!appendfile "${HackyVIFileVersion_cmd}" `FOR /F "usebackq tokens=* delims=" %%A IN ("%eh%1.rc") DO ($\n`
!appendfile "${HackyVIFileVersion_cmd}" ` FOR /F "usebackq" %%B IN ('%%A') DO ($\n`
!appendfile "${HackyVIFileVersion_cmd}" ` if "%%~B"=="FILEVERSION" (>> "%eh%2.rc" echo.FILEVERSION %~4) else (>> "%eh%2.rc" echo.%%A)$\n`
!appendfile "${HackyVIFileVersion_cmd}" ` )$\n`
!appendfile "${HackyVIFileVersion_cmd}" `)$\n`
!appendfile "${HackyVIFileVersion_cmd}" `call "%~3" /fo "%eh%.res" /r "%eh%2.rc"$\n`
!appendfile "${HackyVIFileVersion_cmd}" `call "%rh%" -addoverwrite "%eh%", "%eh%", "%eh%.res", versioninfo,1,$\n`
!appendfile "${HackyVIFileVersion_cmd}" `del "%eh%2.rc"&del "%eh%1.rc"&del "%eh%.res"&del "%~0"`
!packhdr "$%TEMP%\exehead${HackyVIFileVersion_id}.tmp" '"${HackyVIFileVersion_cmd}" "${HackyVIFileVersion_id}" "${reshack}" "${gorcjorg}" "${fixedfilever}"'
!undef HackyVIFileVersion_cmd
!undef HackyVIFileVersion_id
!macroend
VIProductVersion "1.2.3.4"
VIAddVersionKey /LANG=1033 FileVersion 5.6.7.8
VIAddVersionKey /LANG=1033 ProductVersion "1.2.3.4"
VIAddVersionKey /LANG=1033 Comments "A test comment"
!insertmacro HackyVIFileVersion "C:\tools\ResHacker.exe" "C:\tools\GoRC.exe" "5,6,7,8"
...你最終得到這個版本的資源：
1 VERSIONINFO
FILEVERSION 5,6,7,8
PRODUCTVERSION 1,2,3,4
FILEOS 0x4
FILETYPE 0x1
{
BLOCK "StringFileInfo"
{
BLOCK "040904e4"
{
VALUE "Comments", "A test comment"
VALUE "FileVersion", "5.6.7.8"
VALUE "ProductVersion", "1.2.3.4"
}
}
BLOCK "VarFileInfo"
{
VALUE "Translation", 0x0409 0x04E4
}
}
我想我會提到這個bug的顯而易見的解決方法。
當使用NSIS 2.46設置VIProductVersion您文件版本然後用VIAddVersionKey設置的ProductVersion，你還需要設置FILEVERSION避免NSIS編譯器警告。
VIProductVersion ${INSTALLER_VERSION}
VIAddVersionKey ProductName ${PROGRAM_NAME}
VIAddVersionKey FileVersion ${INSTALLER_VERSION}
VIAddVersionKey ProductVersion ${PROGRAM_VERSION}
...
謝謝你的回答，它真的幫助我瞭解'VIProductVersion'的工作原理。它的確應該按照你的建議進行擴展，或者至少應該在NSIS文檔中增加一條評論。 –
VIFileVersion現已添加到SVN ... – Anders