用XSL翻譯數據

Question

我正在使用XSL文件來轉換另一個使用Y和N值而不是true和false的XML。我怎麼能一次定義所有的Y或N都應該成爲真或假，而不必在我訪問原始數據的每一行中都做到這一點？

原始XML：

<whatever> 
<water>N</water> 
<electricity>Y</electricity> 
<internet>Y</internet> 
</whatever> 

XSL，現在我不得不每一次在Y爲真翻譯：

<whatever> 
<water><!-- xsl translation here --></water> 
<electricity><!-- xsl translation here --></electricity> 
<internet><!-- xsl translation here --></internet> 
</whatever> 

理想XSL：

<whatever> 
<!-- Something magic that will automatically change all value-of output--> 
<water><xsl:value-of select="//water"/></water> 
<electricity><xsl:value-of select="//electricity"/></electricity> 
<internet><xsl:value-of select="//internet"/></internet> 
</whatever> 

輸出：

<whatever> 
<water>false</water> 
<electricity>true</electricity> 
<internet>true</internet> 
</whatever> 

Answer 1

一個更簡單，更高效的XSLT 1.0樣式表會...

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

<xsl:template match="@*|node()"> 
<xsl:copy> 
    <xsl:apply-templates select="@*|node()"/> 
</xsl:copy> 
</xsl:template> 

<xsl:template match="text()[.='Y']"> 
<xsl:value-of select="'true'" /> 
</xsl:template> 

<xsl:template match="text()[.='N']"> 
<xsl:value-of select="'false'" /> 
</xsl:template> 

</xsl:stylesheet> 

---

...或等價...

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

<xsl:template match="@*|node()"> 
<xsl:copy> 
    <xsl:apply-templates select="@*|node()"/> 
</xsl:copy> 
</xsl:template> 

<xsl:template match="text()[.='Y']">true</xsl:template> 
<xsl:template match="text()[.='N']">false</xsl:template> 

</xsl:stylesheet> 

Answer 2

使用標識模板來處理XML並保持相同的結構。

添加一個將文本節點「Y」和「N」轉換爲true和false的模板。

<?xml version="1.0" ?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

    <xsl:output method="xml" omit-xml-declaration="yes"/> 

    <!-- put your templates here --> 
<xsl:template match="text()"> 
    <xsl:choose> 
    <xsl:when test=".='Y'">true</xsl:when> 
    <xsl:when test=".='N'">false</xsl:when> 
    <xsl:otherwise><xsl:copy/></xsl:otherwise> 
    </xsl:choose> 
</xsl:template> 

    <!-- identity templates --> 
    <xsl:template match="*"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*"/> 
      <xsl:apply-templates select="node()"/> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="@*|comment()|processing-instruction()"> 
     <xsl:copy/> 
    </xsl:template> 

</xsl:stylesheet> 

關於身份模板的更多信息，請參閱。

Answer 3

只需使用：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
    <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 
<xsl:template match="text()[. = 'Y' or . = 'N']"> 
    <xsl:value-of select=". = 'Y'"/> 
</xsl:template> 
</xsl:stylesheet> 

當所提供的XML文檔施加這種轉變：

<whatever> 
    <water>N</water> 
    <electricity>Y</electricity> 
    <internet>Y</internet> 
</whatever> 

有用，正確的結果產生：

<whatever> 
    <water>false</water> 
    <electricity>true</electricity> 
    <internet>true</internet> 
</whatever> 

說明：

1. 使用並覆蓋identity rule。

2. 所有你想在壓倒一切的模板來輸出簡單的XPath表達式的結果. = 'Y'